forked from thomasxm/shellcode
-
Notifications
You must be signed in to change notification settings - Fork 0
Expand file tree
/
Copy pathzx7mini_depack_x86.asm
More file actions
72 lines (67 loc) · 2.17 KB
/
zx7mini_depack_x86.asm
File metadata and controls
72 lines (67 loc) · 2.17 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
; -----------------------------------------------------------------------------
; ZX7 mini by Einar Saukas, Antonio Villena
; "Standard" version (43/39 bytes only)
; -----------------------------------------------------------------------------
; Parameters:
; HL: source address (compressed data)
; DE: destination address (decompressing)
; -----------------------------------------------------------------------------
; Converted to x86 assembly, by odzhan (22/02/2020, 67 bytes)
;
; mapping of registers:
;
; A => AL
; BC => ECX
; D => DH
; E => DL
; HL => ESI
; DE => EDI
;
bits 32
%ifndef BIN
global zx7_depack
global _zx7_depack
%endif
zx7_depack:
_zx7_depack:
pushad
mov esi, [esp+32+4] ; esi = in
mov edi, [esp+32+8] ; edi = out
call init_getbit
getbit:
add al, al ; add a, a
jnz exit_getbit ; ret nz
lodsb ; ld a, (hl)
; inc hl
adc al, al ; adc a, a
exit_getbit:
ret
init_getbit:
pop ebp ;
mov al, 80h ; ld a, $80
copyby:
movsb ; ldi
mainlo:
call ebp ; call getbit
jnc copyby ; jr nc, copyby
push 1 ; ld bc, 1
pop ecx
lenval:
call ebp ; call getbit
rcl cl, 1 ; rl c
jc exit_depack ; ret c
call ebp ; call getbit
jnc lenval ; jr nc, lenval
push esi ; push hl
movzx edx, byte[esi] ; ld l, (hl)
mov esi, edi
sbb esi, edx ; sbc hl, de
rep movsb ; ldir
pop esi ; pop hl
inc esi ; inc hl
jmp mainlo ; jr mainlo
exit_depack:
sub edi, [esp+32+8] ;
mov [esp+28], edi
popad
ret