-
Notifications
You must be signed in to change notification settings - Fork 1
Expand file tree
/
Copy pathqueue.asm
More file actions
184 lines (153 loc) · 2.97 KB
/
queue.asm
File metadata and controls
184 lines (153 loc) · 2.97 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
; -----------------------
; Title: Queue
; Author: Measter
; Date: 2013/10/29
; -----------------------
; Revisions
; 1 : Initial Release.
; 2 : Added macro.
.include <memory/alloc.asm>
.macro create_queue(dest)
set push, 0
jsr create_queue_func
set dest, pop
.endmacro
.macro delete_queue (ptr)
set push, ptr
jsr delete_queue_func
set ptr, pop
.endmacro
.macro pop_queue (queue_ptr, data)
set push, queue_ptr
jsr pop_queue_func
set data, pop
.endmacro
.macro push_queue (queue_ptr, data, err)
set push, queue_ptr
set push, data
jsr push_queue_func
set err, pop
.endmacro
; Queue Header Structure.
; +0 : Number of items in queue.
; +1 : First item in queue. Null address is 0xFFFF.
; +2 : Last item in queue. Null address is 0xFFFF.
; Queue Item Structure.
; +0 : Next item in queue.
; +1 : Data.
; Creates a new Queue, and returns the header address.
; Input
; SP+0 : None.
; Output
; SP+0 : Address of queue header. Will return 0xFFFF on error.
:create_queue_func
set push, z
set z, sp
add z, 2
; Memory for header.
mem_alloc(0x3, [z])
set z, [z] ; Z = address of queue header.
; Unable to allocate.
ife z, 0xFFFF
set pc, .exit
set [z], 0
set [z+1], 0xFFFF
set [z+2], 0xFFFF
:.exit
set z, pop
set pc, pop
; Deletes a queue.
; Input
; SP+0 : Address of header.
; Output
; SP+0 : 0xFFFF if error, else 0x0.
:delete_queue_func
set push, z
set z, sp
add z, 2
set push, a
set push, b
set a, [z]
ife [a+0], 0
set pc, .delete_header
; Delete contents.
:.empty_loop_start
pop_queue (a, b)
ifg [a+0], 0
set pc, .empty_loop_start
:.empty_loop_exit
:.delete_header
mem_free (a)
set [z], a
set b, pop
set a, pop
set z, pop
set pc, pop
; Dequeues an item.
; Input
; SP+0 : Queue header.
; Output
; SP+0 : Data.
:pop_queue_func
set push, z
set z, sp
add z, 2
set push, a
set push, b
set a, [z] ; A = queue header.
ife [a+0], 0
set pc, .exit ; Empty queue.
set b, [a+1]; ; B = next item.
set [z], [b+1] ; Return data.
; Deallocate.
set [a+1], [b+0] ; Set next link.
sub [a+0], 1 ; Decrement count.
ife [a+2], b
set [a+2], 0xFFFF ; If last item, null last link.
mem_free (b)
:.exit
set b, pop
set a, pop
set z, pop
set pc, pop
; Enqueue an item.
; Input
; SP+1 : Queue Header.
; SP+0 : Data to queue.
; Output
; SP+0 : 0xFFFF if error, else 0x0.
:push_queue_func
set push, z
set z, sp
add z, 2
set push, a
set push, i
set push, x
set i, [z+1] ; I = queue header.
mem_alloc(2, a) ; A = new item.
ifn a, 0xFFFF
set pc, .no_error
set [z], 0xFFFF
set pc, .exit
:.no_error
set [a+0], 0xFFFF ; Null last link.
set [a+1], [z] ; Set data.
ifn [i+0], 0 ; Count
set pc, .last_item
; First item.
set [i+1], a
set [i+2], a
set pc, .exit_no_error
:.last_item
set x, [i+2] ; Last item.
set [x+0], a ; Next link.
set [i+2], a ; Last link.
:.exit_no_error
add [i+0], 1 ; Increment count.
set [z], 0x0
:.exit
set x, pop
set i, pop
set a, pop
set z, pop
set pc, pop