-
Notifications
You must be signed in to change notification settings - Fork 0
Expand file tree
/
Copy pathpsgplayer.s
More file actions
303 lines (247 loc) · 7.38 KB
/
psgplayer.s
File metadata and controls
303 lines (247 loc) · 7.38 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
# vim: set tabstop=4 :
#---------------------------------------------------------------------------------
# PLAYING MODULE FOR TWO PSG.PACKED FILES BY VLADIMIR "KUVO" KUTYAKOV / CSI, 02022
# based on psg_player_v1.0 for Z80 by tmk & bfox
#
# SPECIAL FOR AZBK BY MAXIM BAGAEV
#
# PLATFORM: Elektronika MS 0511 + Aberrant Sound Module
# COMPILER: GNU Assembler
#
# BK-0011M version adapted for Electronika MS0511 by aberrant_hacker
#---------------------------------------------------------------------------------
#!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
#!!!
#!!! This file is included in UNIP2PSG.mac by .INCLUDE directive
#!!!
#!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
psgplayer.MUS_PLAY:
MOV SP, SP_CALL
MOV $MUS_1_PARAMS, R5 # AY1, FILE1 (see UNIP2PSG.mac)
CALL PLAY_ONE_PSG
MOV $MUS_2_PARAMS, R5 # AY2, FILE2 (see UNIP2PSG.mac)
PLAY_ONE_PSG:
MOV MUS_PAUSE(R5), R0
BZE 10$
DEC R0
MOV R0, MUS_PAUSE(R5)
RETURN
10$: MOV CUR_MUS_ADDR(R5), @$PBPADR
MOV MUS_DATA_REG(R5), R1
MUS_ADDR_NEXT:
MOVB (R1), R0
INC @$PBPADR
TSTB R0
BPL 10$
JMP MUS_LINKS
10$: BZE MUS_PAUSE_N
SUB $0100, R0
BPL MUS_PSG2
SUB $0177740, R0
BPL MUS_PSG2_INDEX
ADD $021, R0
BNZ 2$
CMP @$FILE_1_PARAMS + MUS_DATA_REG, $PBP2DT # finished playing from bank 2 ?
BEQ 1$ # yes, stop the music
# no, switch to bank 2
MOV $PBP2DT, @$FILE_1_PARAMS + MUS_DATA_REG
MOV $PBP2DT, @$FILE_2_PARAMS + MUS_DATA_REG
MOV $0100000,@$FILE_1_PARAMS + MUS_DATA_ADDR
MOV $0125034,@$FILE_2_PARAMS + MUS_DATA_ADDR
CLR MUS_STOP_NEED
BR MUS_LOOP
1$: #CLR @$PLAY_NOW
MOV $CPU.Title.PLAY_NOW, @$PBPADR
CLR @$PBP12D
JMP MUS_STOP
2$: BMI MUS_PSG1
MUS_PAUSE16:
DEC R0
MOV R0, MUS_PAUSE(R5)
JMP MUS_COM_END
MUS_PSG1:
SUB $0177762, R0
MOV AY_PORT(R5), R2
MOV R0, (R2) # AY REGISTER
MOVB (R1), (R2) # VALUE
INC @$PBPADR
JMP MUS_COM_END
MUS_PAUSE_N:
MOVB (R1), MUS_PAUSE(R5)
INC @$PBPADR
JMP MUS_COM_END
MUS_LOOP:
.equiv SP_CALL, .+2
MOV $0, SP
JMP psgplayer.MUS_INIT
MUS_PSG2:
MOVB (R1), R2
INC @$PBPADR
BR MUS_PSG2_OUT
MUS_PSG2_INDEX:
PUSH @$PBPADR
MOV MUS_DATA_ADDR(R5), R2
ASL R0
ADD R0, R2
MOV R2,@$PBPADR
MOVB (R1), R0
INC @$PBPADR
MOVB (R1), R2
POP @$PBPADR
MUS_PSG2_OUT:
CLR R3
MOV AY_PORT(R5), R4
ASR R2
BCC 10$
MOV R3, (R4) # AY REGISTER
MOVB (R1), (R4) # VALUE
INC @$PBPADR
10$: INC R3
.rept 7
ASR R2
BCC .+10 # !
MOV R3, (R4) # AY REGISTER
MOVB (R1), (R4) # VALUE
INC @$PBPADR
INC R3
.endr
.rept 5
ASR R0
BCC .+10 # !
MOV R3, (R4) # AY REGISTER
MOVB (R1), (R4) # VALUE
INC @$PBPADR
INC R3
.endr
ASR R0
BCC MUS_COM_END
MOV R3, (R4) # AY REGISTER
MOVB (R1), (R4) # VALUE
INC @$PBPADR
MUS_COM_END:
MOV @$PBPADR, CUR_MUS_ADDR(R5)
MOV BEGIN_MUS_STACK_ADDR(R5), R0
MOV CUR_MUS_STACK_ADDR(R5), @$PBPADR
MOV $MAX_INNER_CALL, R3
10$: CMP R0, @$PBPADR
BEQ 1$
DEC (R0)+
BZE MUS_CALL_RET
TST (R0)+ # ADD $2, R0
SOB R3, 10$
1$: RETURN
MUS_CALL_RET:
MOV (R0), R2
TST -(R0) # SUB $2,R0
MOV R0, CUR_MUS_STACK_ADDR(R5)
MOV R2, CUR_MUS_ADDR(R5)
RETURN
MUS_LINKS:
CLR R2
BISB (R1), R2
INC @$PBPADR
MOV CUR_MUS_STACK_ADDR(R5), R3
SUB $0177700, R0
BMI MUS_CALL_ONE
MOV R0, R4
MUS_CALL_N:
CLR R0
BISB (R1), R0
INC @$PBPADR
MOV R0, (R3)+
MOV @$PBPADR, (R3)+
MOV R3, CUR_MUS_STACK_ADDR(R5)
SWAB R4
BISB R2, R4
SUB R4, @$PBPADR
JMP MUS_ADDR_NEXT
MUS_CALL_ONE:
SUB $0177700, R0
MOV $1, (R3)+
MOV @$PBPADR, (R3)+
MOV R3, CUR_MUS_STACK_ADDR(R5)
SWAB R0
BISB R2, R0
SUB R0, @$PBPADR
JMP MUS_ADDR_NEXT
psgplayer.MUS_INIT:
MOV $FILE_1_PARAMS, R5
CALL SETUP_PSG_PARAM
.equiv MUS_STOP_NEED, .+2
TST $-1
BZE 10$
CALL MUS_STOP
10$: MOV $FILE_2_PARAMS, R5
CALL SETUP_PSG_PARAM
TST MUS_STOP_NEED
BNE MUS_STOP
MOV R5, MUS_STOP_NEED
MOV PC, R5
ADD $psgplayer.MUS_PLAY-., R5
PUSH R5
RETURN
SETUP_PSG_PARAM:
MOV (R5)+, R0 # R0 = data register
MOV (R5)+, R1 # R1 = music address
PUSH R5
MOV R0, (R5)+ # R0 -> MUS_DATA_REG
MOV R1, (R5)+ # R1 -> MUS_DATA_ADDR
ADD $INI_INDEXMASK_SIZE, R1 # R1 = music address + 64
MOV R1, (R5)+ # R1 -> MUS_LOOP_ADDR
MOV R1, (R5)+ # R1 -> CUR_MUS_ADDR
MOV R5, R0 # R0 = addr of MUS_STACK
MOV $MAX_INNER_CALL_SIZE_WORDS, R1
10$:
CLR (R5)+ # clears mus_stack
SOB R1, 10$
MOV R0, (R5)+ # MUS_STACK -> BEGIN_MUS_STACK_ADDR
MOV R0, (R5)+ # MUS_STACK -> CUR_MUS_STACK_ADDR
CLR (R5)+ # -> MUS_PAUSE
POP R5
RETURN
MUS_STOP:
# SEND ZERO TO ALL REGISTERS AY
MOV AY_PORT(R5), R4
MOV $015, R1
CLR R2
10$: MOV R1, (R4) # AY REGISTER
MOVB R2, (R4) # VALUE
DEC R1
BPL 10$
RETURN
psgplayer.MUTE:
MOV $MUS_1_PARAMS, R5
CALL MUS_STOP
MOV $MUS_2_PARAMS, R5
BR MUS_STOP
# MUS_PARAMS
.equiv INI_INDEXMASK_SIZE, 64
.equiv INI_MUS_LOOP, 0
.equiv MAX_INNER_CALL, 7
.equiv MAX_INNER_CALL_SIZE, MAX_INNER_CALL * 8
.equiv MAX_INNER_CALL_SIZE_WORDS, MAX_INNER_CALL_SIZE >> 1
# MUS_PARAMS_OFFSETS
.equiv MUS_DATA_REG, 0
.equiv MUS_DATA_ADDR, MUS_DATA_REG + 2
.equiv MUS_LOOP_ADDR, MUS_DATA_ADDR + 2
.equiv CUR_MUS_ADDR, MUS_LOOP_ADDR + 2
.equiv MUS_STACK, CUR_MUS_ADDR + 2
.equiv BEGIN_MUS_STACK_ADDR, MUS_STACK + MAX_INNER_CALL_SIZE
.equiv CUR_MUS_STACK_ADDR, BEGIN_MUS_STACK_ADDR + 2
.equiv MUS_PAUSE, CUR_MUS_STACK_ADDR + 2
.equiv AY_PORT, MUS_PAUSE + 2
.equiv SIZE_OF_MUS_PARAMS, AY_PORT - MUS_DATA_REG
#PSG_1_PARAMS:
AY_1_PARAMS: .word 0b0100111100000000
.word 0
FILE_1_PARAMS: .word PBP1DT
.word 0100000
MUS_1_PARAMS: .space SIZE_OF_MUS_PARAMS
psgplayer.PSG0: .word PSG0
#PSG_2_PARAMS:
AY_2_PARAMS: .word 0b1000111100000000
.word 1
FILE_2_PARAMS: .word PBP1DT
.word 0136120
MUS_2_PARAMS: .space SIZE_OF_MUS_PARAMS
psgplayer.PSG1: .word PSG1