; Cute Mouse Driver - a tiny mouse driver

;

; Copyright (c) 1997-2002 Nagy Daniel <[email protected]>

; DirtyRat specific changes by Scrap Computing 2023

;

; BIOS wheel mouse support: Ported from Konstantin Koll's public

; domain code into Cute Mouse by Eric Auer 2007 (places marked -X-)

;

; This program is free software; you can redistribute it and/or modify

; it under the terms of the GNU General Public License as published by

; the Free Software Foundation; either version 2 of the License, or

; (at your option) any later version.

;

; This program is distributed in the hope that it will be useful,

; but WITHOUT ANY WARRANTY; without even the implied warranty of

; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the

; GNU General Public License for more details.

;

; You should have received a copy of the GNU General Public License

; along with this program; if not, write to the Free Software

; Foundation, Inc., 51 Franklin St - Fifth Floor, Boston, MA 02110-1301 USA

; -X- no longer: 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA

;

; NOTE: memcopy and MOVSEG_ have "assume..." as side effects!

; %pagesize 255

; %noincl

;%macs

; %nosyms

;%depth 0

; %linum 0

;%pcnt 0

;%bin 0

; warn

; locals

DRTRATVER equ <"0.1"> ; dirty rat version

CTMVER equ <"2.1"> ; major driver version

CTMRELEASE equ <"2.1 beta4"> ; full driver version with suffixes

driverversion equ 705h ; imitated Microsoft driver version

; at least 705h because our int 33 function _26 operates in 7.05+ style

FASTER_CODE = 0 ; optimize by speed instead size

OVERFLOW_PROTECT = 0 ; prevent variables overflow

FOOLPROOF = 1 ; check driver arguments validness

USE28 = 0 ; include code for INT 33/0028 function

USERIL = 0 ; include code for INT 10/Fn EGA functions

; %define PS2DEBUG 1 ; print debug messages for PS2serv calls

;------------------------------------------------------------------------

include asmlib/asm.mac

; *** include asmlib/hll.mac ; if_ loop_ countloop_ etc - TASM specific

include asmlib/code.def

include asmlib/code.mac

include asmlib/macro.mac

include asmlib/bios/area0.def ; ** int11 flags and various 40:xx gfx info

; HW_PS2 equ 4 ; bit set in int 11h returned AX if PS/2 mouse present

; VIDEO_control VIDEO_switches VIDEO_width VIDEO_pageoff VIDEO_mode

; VIDEO_switches VIDSW_feature0 VIDSW_display VIDEO_ptrtable@

; VPARAM_SEQC VIDEO_paramtbl@ VIDEO_lastrow VIDEO_pageno

include asmlib/convert/digit.mac ; ** only count2x uses digits in ascii

include asmlib/convert/count2x.mac ; ** only used as _word_hex for i/o port

include asmlib/dos/mcb.def ; ** small, used to set ownerid and name

include asmlib/dos/psp.def ; ** only dos_exit env_seg cmdline_len psp_tsr used

; include asmlib/dos/file.mac ; was only used once - dosclosefile

include asmlib/dos/mem.mac

; include asmlib/hard/pic8259a.def ; only pic1_ocw2, pic1_imr const used:

PIC1_OCW2 equ 20h

PIC1_IMR equ 21h

include asmlib/hard/uart.def

USE_286 equ <(@CPU and 4)>

USE_386 equ <(@CPU and 8)>

_ARG_DI_ equ <word ptr [bp]>

_ARG_SI_ equ <word ptr [bp+2]>

_ARG_BP_ equ <word ptr [bp+4]>

if USE_286

_ARG_BX_ equ <word ptr [bp+8]>

_ARG_DX_ equ <word ptr [bp+10]>

_ARG_CX_ equ <word ptr [bp+12]>

_ARG_AX_ equ <word ptr [bp+14]>

_ARG_ES_ equ <word ptr [bp+16]>

_ARG_DS_ equ <word ptr [bp+18]>

; arg offset: far pointer plus 8+2 words (push 2 segs, pusha)

_ARG_OFFS_ = 24

PUSHALL equ <pusha>

POPALL equ <popa>

else ; USE_286

_ARG_BX_ equ <word ptr [bp+6]>

_ARG_DX_ equ <word ptr [bp+8]>

_ARG_CX_ equ <word ptr [bp+10]>

_ARG_AX_ equ <word ptr [bp+12]>

_ARG_ES_ equ <word ptr [bp+14]>

_ARG_DS_ equ <word ptr [bp+16]>

_ARG_OFFS_ = 22

PUSHALL macro

push ax

push cx

push dx

push bx

push bp

push si

push di

endm

POPALL macro

pop di

pop si

pop bp

pop bx

pop dx

pop cx

pop ax

endm

endif ; USE_286

nl equ <13,10>

eos equ <0>

POINT struc

X dw ?

Y dw ?

POINT ends

PS2serv macro serv:req,errlabel ; :vararg

mov ax,serv

ifdef PS2DEBUG

push ax

mov al,'<'

int 29h

pop ax

push ax

and al,15 ; assume ax is c20n, only show low nibble

add al,30h ; convert to digit

int 29h

mov al,'/'

int 29h

mov al,bh ; low nibble of bh is interesting, too

add al,30h ; (func 7: es bx is pointer)

int 29h

pop ax

endif ; ifdef PS2DEBUG

int 15h

ifdef PS2DEBUG

pushf

push ax

mov al,20h ; space

adc al,0 ; if carry, exclamation mark

int 29h

pop ax

push ax

mov al,ah

add al,30h ; usually ah is only 0..9 status

int 29h

mov al,'/'

int 29h

mov al,bh ; func 1, 4: device id (1: bl is aa if okay)

add al,30h ; can be ff+30 or aa+30 now :-p

int 29h

mov al,'>'

int 29h

pop ax

popf

endif ; ifdef PS2DEBUG

ifnb <errlabel>

jc errlabel

test ah,ah

jnz errlabel

endif

endm

;========================== SEGMENTS DEFINITION ==========================

.model tiny

assume ss:nothing

@TSRcode equ <DGROUP>

@TSRdata equ <DGROUP>

; TSR ends at TSRend, roughly line 3000 of the 4000 lines of ctmouse

TSRcref equ <offset @TSRcode> ; offset relative TSR code group

TSRdref equ <offset @TSRdata> ; - " - data

coderef equ <offset @code> ; offset relative main code group

dataref equ <offset @data> ; - " - data

.code

org 0

TSRstart label byte

org 100h ; .COM style program

start: jmp real_start

TSRavail label byte ; initialized data may come from here

;========================== UNINITIALIZED DATA ==========================

;!!! WARNING: don't init variables in uninitialized section because

; they will not be present in the executable image

org PSP_TSR-3*16 ; reuse part of PSP

spritebuf db 3*16 dup (?) ; copy of screen sprite in modes 4-6

;----- application state -----

;!!! WARNING: variables order between RedefArea and szDefArea must be

; syncronized with variables order after DefArea

even

SaveArea = $

RedefArea = $

mickey8 POINT <> ; mickeys per 8 pixel ratios

;;*doublespeed dw ? ; double-speed threshold (mickeys/sec)

senscoeff POINT <> ; mickeys sensitivity, ~[1/3..3.0]*256

sensval POINT <> ; original 001A sensitivity values-1

startscan dw ? ; screen mask/cursor start scanline

endscan dw ? ; cursor mask/cursor end scanline

;----- hotspot, screenmask and cursormask must follow as is -----

hotspot POINT <> ; cursor bitmap hot spot

screenmask db 2*16 dup (?) ; user defined screen mask

cursormask db 2*16 dup (?) ; user defined cursor mask

nocursorcnt db ? ; 0=cursor enabled, else hide counter

;;*nolightpen? db ? ; 0=emulate light pen

even

szDefArea = $ - RedefArea ; initialized by softreset_21

rangemax POINT <> ; horizontal/vertical range max

upleft POINT <> ; upper left of update region

lowright POINT <> ; lower right of update region

pos POINT <> ; virtual cursor position

granpos POINT <> ; granulated virtual cursor position

UIR@ dd ? ; user interrupt routine address

even

ClearArea = $

sensround POINT <> ; rounding error in applying

; sensitivity for mickeys

rounderr POINT <> ; same in conversion mickeys to pixels

even

szClearArea1 = $ - ClearArea ; cleared by setpos_04

rangemin POINT <> ; horizontal/vertical range min

even

szClearArea2 = $ - ClearArea ; cleared by setupvideo

cursortype db ? ; 0 - software, else hardware

callmask db ? ; user interrupt routine call mask

mickeys POINT <> ; mouse move since last access

BUTTLASTSTATE struc

counter dw ?

lastrow dw ?

lastcol dw ?

BUTTLASTSTATE ends

buttpress BUTTLASTSTATE <>

buttrelease BUTTLASTSTATE <>

wheel BUTTLASTSTATE <> ; wheel counter since last access

wheelUIR db ? ; wheel counter for UIR

even

szClearArea3 = $ - ClearArea ; cleared by softreset_21

szSaveArea = $ - SaveArea

if USERIL ; -X-

;----- registers values for RIL -----

;!!! WARNING: registers order and RGROUPDEF contents must be fixed

even

VRegsArea = $

regs_SEQC db 5 dup (?)

reg_MISC db ?

regs_CRTC db 25 dup (?)

regs_ATC db 21 dup (?)

regs_GRC db 9 dup (?)

reg_FC db ?

reg_GPOS1 db ?

reg_GPOS2 db ?

DefVRegsArea = $

def_SEQC db 5 dup (?)

def_MISC db ?

def_CRTC db 25 dup (?)

def_ATC db 21 dup (?)

def_GRC db 9 dup (?)

def_FC db ?

def_GPOS1 db ?

def_GPOS2 db ?

szVRegsArea = $ - DefVRegsArea

; ERRIF (szVRegsArea ne 64 or $-VRegsArea ne 2*64) "VRegs area contents corrupted!"

else

crtc dw ? ; 3d4 or 3b4

endif ; -X- USERIL

;----- old interrupt vectors -----

oldint33 dd ? ; old INT 33 handler address

oldIRQaddr dd ? ; old IRQ handler address

;=========================== INITIALIZED DATA ===========================

even

TSRdata label byte

if (TSRdata lt TSRavail)

;echo TSR uninitialized data area too small ( No error ).

ORG TSRavail

endif

DefArea = $

POINT <8,16> ; mickey8

POINT <1*256,1*256> ; senscoeff

POINT <49,49> ; sensval

;;* dw 64 ; doublespeed

dw 77FFh,7700h ; startscan, endscan

POINT <0,0> ; hotspot

dw 0011111111111111b ; screenmask

dw 0001111111111111b

dw 0000111111111111b

dw 0000011111111111b

dw 0000001111111111b

dw 0000000111111111b

dw 0000000011111111b

dw 0000000001111111b

dw 0000000000111111b

dw 0000000000011111b

dw 0000000111111111b

dw 0000000011111111b

dw 0011000011111111b

dw 1111100001111111b

dw 1111100001111111b

dw 1111110011111111b

dw 0000000000000000b ; cursormask

dw 0100000000000000b

dw 0110000000000000b

dw 0111000000000000b

dw 0111100000000000b

dw 0111110000000000b

dw 0111111000000000b

dw 0111111100000000b

dw 0111111110000000b

dw 0111110000000000b

dw 0110110000000000b

dw 0100011000000000b

dw 0000011000000000b

dw 0000001100000000b

dw 0000001100000000b

dw 0000000000000000b

db 1 ; nocursorcnt

;;* db 0 ; nolightpen?

db 0 ; JWASM would use 0fch, "CLD" as pad byte??

even

; ERRIF ($-DefArea ne szDefArea) "Defaults area contents corrupted!"

;----- driver and video state begins here -----

even

granumask POINT <-1,-1>

textbuf label word

buffer@ dd ? ; pointer to screen sprite copy

cursor@ dw -1,0 ; cursor sprite offset in videoseg;

; -1=cursor not drawn

videoseg equ <cursor@[2]> ; 0=not supported video mode

UIRunlock db 1 ; 0=user intr routine is in progress

videolock db 1 ; drawing: 1=ready,0=busy,-1=busy+queue

newcursor db 0 ; 1=force cursor redraw

;----- table of pointers to registers values for RIL -----

REGSET struc

rgroup dw ?

regnum db ?

regval db ?

REGSET ends

db 0 ; JWASM would use 0fch, "CLD" as pad byte??

even

dw (vdata1end-vdata1)/(size REGSET)

vdata1 REGSET <10h,1>,<10h,3>,<10h,4>,<10h,5>,<10h,8>,<08h,2>

vdata1end label word

dw (vdata2end-vdata2)/(size REGSET)

vdata2 REGSET <10h,1,0>,<10h,4,0>,<10h,5,1>,<10h,8,0FFh>,<08h,2,0Fh>

vdata2end label byte

RGROUPDEF struc

port@ dw ?

regs@ dw ?

def@ dw ?

regscnt db 1

rmodify? db 0

RGROUPDEF ends

if USERIL ; -X-

even

videoregs@ label RGROUPDEF

RGROUPDEF <3D4h,regs_CRTC,def_CRTC,25> ; CRTC

RGROUPDEF <3C4h,regs_SEQC,def_SEQC,5> ; Sequencer

RGROUPDEF <3CEh,regs_GRC, def_GRC, 9> ; Graphics controller

RGROUPDEF <3C0h,regs_ATC, def_ATC, 20> ; VGA attrib controller

RGROUPDEF <3C2h,reg_MISC, def_MISC> ; VGA misc output and input

RGROUPDEF <3DAh,reg_FC, def_FC> ; Feature Control

RGROUPDEF <3CCh,reg_GPOS1,def_GPOS1> ; Graphics 1 Position

RGROUPDEF <3CAh,reg_GPOS2,def_GPOS2> ; Graphics 2 Position

endif ; -X- USERIL

;============================= IRQ HANDLERS =============================

;========================================================================

IRQhandler proc

assume ds:nothing,es:nothing

cld

push ds

push es

PUSHALL

MOVSEG ds,cs,,@TSRdata

; CODE_ MOV_CX IOdone,<db ?,0> ; processed bytes counter

OPCODE_MOV_CX

IOdone db ?,0

; -X- IRQproc label byte ; "mov al,OCW2<OCW2_EOI>"

; -X- j PS2proc ; if serial mode

; -X- out PIC1_OCW2,al ; {20h} end of interrupt

; out_ PIC1_OCW2,%OCW2<OCW2_EOI>

mov al,20h

out PIC1_OCW2,al

; CODE_ MOV_DX IO_address,<dw ?> ; UART IO address

OPCODE_MOV_DX

IO_address dw ?

movidx dx,RBR_index

in al,dx ; {3F8h} flush receive buffer

call_ mouseproc,MSLTproc ; never PS/2

jmp rethandler

IRQhandler endp

assume ds:@TSRdata

UserIRQ db 3 ; The user-defined IRQ number

UserIOAddr dw 2e8h ; The user-defined I/O address

;========================================================================

; Enable serial interrupt in PIC

;========================================================================

;

; In: none

; Out: none

; Use: IO_address

; Modf: AX, DX, SI, IOdone, MSLTbuttons

; Call: INT 21/25

;

enableUART proc

;----- set new IRQ handler

mov dx,TSRcref:IRQhandler ; -X- IRQintnum 0 means none

; CODE_ MOV_AX IRQintnum,<db 0,25h> ; INT number of selected IRQ

OPCODE_MOV_AX

IRQintnum db 0,25h

int 21h ; set INT in DS:DX

in al,PIC1_IMR ; {21h} get IMR

; CODE_ AND_AL notPIC1state,<db ?> ; clear bit to enable interrupt

OPCODE_AND_AL

notPIC1state db ?

out PIC1_IMR,al ; {21h} enable serial interrupts

ret

enableUART endp

;========================================================================

; Disable serial interrupt of PIC

;========================================================================

;

; In: none

; Out: none

; Use: IO_address, oldIRQaddr

; Modf: AX, DX

; Call: INT 21/25

;

disableUART proc

in al,PIC1_IMR ; {21h} get IMR

; CODE_ OR_AL PIC1state,<db ?> ; set bit to disable interrupt

OPCODE_OR_AL

PIC1state db ?

out PIC1_IMR,al ; {21h} disable serial interrupts

;----- restore old IRQ handler

push ds

mov ax,word ptr [IRQintnum] ; AH=25h

lds dx,[oldIRQaddr]

assume ds:nothing

int 21h ; set INT in DS:DX

pop ds

ret

disableUART endp

assume ds:@TSRdata

;========================================================================

; Process the Microsoft/Logitech packet bytes

;========================================================================

MSLTproc proc

; CODE_ MOV_DL MSLTbuttons,<db ?> ; buttons state for MS3/LT/WM

OPCODE_MOV_DL

MSLTbuttons db ?

test al,01000000b ; =40h ; synchro check

; if_ nz ; if first byte

jz @@msltz

mov [IOdone],1 ; request next 2/3 bytes

mov [MSLT_1],al

MSLTCODE1 label byte ; "ret" if not LT/WM

xchg ax,cx ; OPTIMIZE: instead MOV AL,CL

sub al,3 ; if first byte after 3 bytes

jz @@LTWMbutton3 ; then release middle button

ret

; end_

@@msltz:

; if_ ncxz ; skip nonfirst byte at start

jcxz @@msltcxz

inc [IOdone] ; request next byte

loop @@MSLT_3

mov [MSLT_X],al ; keep X movement LO

; end_

@@msltcxz:

@@LTret: ret

@@MSLT_3: loop @@LTWM_4

;mov cl,0

; CODE_ MOV_BX MSLT_1,<db ?,0> ; mouse packet first byte

OPCODE_MOV_BX

MSLT_1 db ?,0

if USE_286

ror bx,2

else

ror bx,1

ror bx,1

endif

; xchg cl,bh ; bits 1-0: X movement HI

xchg bh,cl ; TASM and JWASM use opposite encoding

if USE_286

ror bx,2 ; bits 5-4: LR buttons

else

ror bx,1 ; bits 5-4: LR buttons

ror bx,1

endif

or al,bh ; bits 3-2: Y movement HI

cbw

xchg cx,ax ; CX=Y movement

; CODE_ OR_AL MSLT_X,<db ?>

OPCODE_OR_AL

MSLT_X db ?

cbw

xchg bx,ax ; BX=X movement

;cbw ; clear wheel value

xor al,dl

and al,00000011b ; =3 ; LR buttons change mask

mov dh,al

or dh,bl ; nonzero if LR buttons state

or dh,cl ; changed or mouse moved

MSLTCODE2 label byte

j @@MSLTupdate ; "jnz" if MS3

or al,00000100b ; =4 ; empty event toggles button

j @@MSLTupdate

@@LTWM_4: ;mov ch,0

mov [IOdone],ch ; request next packet

MSLTCODE3 label byte ; if LT "mov cl,3" else

@@LTWMbutton3: mov cl,3 ; if WM "mov cl,2" else "ret"

mov ah,al

shr al,cl

xor al,dl

and ax,111100000100b ; =0F04h

if FASTER_CODE

jz @@LTret ; exit if button 3 not changed

endif

xor bx,bx

xor cx,cx

@@MSLTupdate: xor al,dl ; new buttons state

mov [MSLTbuttons],al

j swapbuttons

MSLTproc endp

;========================================================================

; Update mouse status

;========================================================================

;

; In: AL (new buttons state, 2 or 3 LSB used)

; AH (wheel movemement)

; BX (X mouse movement)

; CX (Y mouse movement)

; Out: none

; Use: callmask, granpos, mickeys, UIR@

; Modf: AX, CX, DX, BX, SI, DI, wheel, wheelUIR, UIRunlock

; Call: updateposition, updatebutton, refreshcursor

;

reverseY proc

neg cx ; reverse Y movement

;j swapbuttons

reverseY endp

swapbuttons proc

test al,00000011b ; =3 ; check the L and R buttons

; if_ odd ; if buttons not same

jpe @@swapeven

; CODE_ XOR_AL swapmask,<db 00000011b> ; 0 if (PS2 xor LEFTHAND)

OPCODE_XOR_AL

swapmask db 00000011b

; end_

@@swapeven:

;j mouseupdate

swapbuttons endp

mouseupdate proc

; CODE_ AND_AX

OPCODE_AND_AX

buttonsmask db 00000111b ; =8

wheelmask db 0

xchg di,ax ; keep btn, wheel state in DI

;----- update mickey counters and screen position

xchg ax,bx ; OPTIMIZE: instead MOV AX,BX

; MOVREG_ bx,<offset X>

xor bx,bx ; MOVREG optimizes mov bx,offset POINT.X into this

call updateposition

xchg ax,cx

; MOVREG_ bl,<offset Y> ; OPTIMIZE: BL instead BX

mov bl,offset POINT.Y

call updateposition

or cl,al ; bit 0=mickeys change flag

;----- update wheel movement

mov ax,[mickeys.Y]

xchg ax,di ; retrieve button, wheel info

xchg dx,ax ; OPTIMIZE: instead MOV DX,AX

mov al,dh ; wheel: signed 4 bit value

xor al,00001000b ; =8

sub al,00001000b ; =8 ; sign extension AL[0:3]->AL

; if_ nz ; if wheel moved

jz @@wheelz

cbw

mov si,TSRdref:wheel

add [si + offset BUTTLASTSTATE.counter],ax ; wheel counter

add [wheelUIR],al ; same, but used for the UIR

mov al,10000000b ; =80h ; bit 7=wheel movement flag

xor bx,bx

call @lastpos

; end_

@@wheelz:

;----- update buttons state

mov dh,dl ; DH=buttons new state

xchg dl,[buttstatus]

xor dl,dh ; DL=buttons change state

if FASTER_CODE

; if_ nz

jz @@btnfastz

endif

xor bx,bx ; buttpress array index

mov al,00000010b ; mask for button 1

call updatebutton

mov al,00001000b ; mask for button 2

call updatebutton

mov al,00100000b ; mask for button 3

call updatebutton

if FASTER_CODE

; end_

@@btnfastz:

endif

;----- call User Interrupt Routine (CX=events mask)

dec [UIRunlock]

; if_ zero ; if user proc not running

jnz @@uirnz

and cl,[callmask]

; if_ nz ; if there is a user events

jz @@maskz

; CODE_ MOV_BX buttstatus,<db 0,0> ; buttons status

OPCODE_MOV_BX

buttstatus db 0,0

xchg bh,[wheelUIR]

mov ax,[granpos.X]

mov dx,[granpos.Y]

xchg ax,cx

mov si,[mickeys.X]

;mov di,[mickeys.Y]

push ds

sti

call [UIR@]

pop ds

; end_

@@maskz:

call refreshcursor

; end_

@@uirnz:

;-----

inc [UIRunlock]

ret

mouseupdate endp

;========================================================================

; In: AX (mouse movement)

; BX (offset X/offset Y)

; Out: AX (1 - mickey counter changed)

; Use: mickey8, rangemax, rangemin, granumask, senscoeff

; Modf: DX, SI, sensround, mickeys, rounderr, pos, granpos

;

updateposition proc

test ax,ax

jz @@uposret

mov si,ax

; if_ sign

jns @@upns

neg ax

; end_

@@upns:

;----- apply sensitivity (SI=movement, AX=abs(SI))

mov dx,word ptr senscoeff[bx] ; ~[1/3..3.0]*256

; cmp ax,4 ; JWASM uses "signed byte" variant

db 03dh, 4, 0 ; "cmp ax, word 4"

; if_ be

ja @@upa

mov ax,si

cmp dh,1 ; skip [-4..4] movements

jae @@newmickeys ; when sensitivity >= 1.0

imul dx ; =mickeys*sensitivity

; else_

jmp short @@upbe

@@upa:

; cmp ax,12 ; JWASM uses "signed byte" variant

db 03dh, 12, 0 ; "cmp ax, word 12"

; if_ ae

if FASTER_CODE

jb @@up2b

mov ax,dx

shl ax,1

add ax,dx ; =sensitivity*3

; else_

jmp short @@up2ae

@@up2b:

mul dx

if USE_286

shr ax,2 ; =sensitivity*min(12,abs(mickeys))/4

else

shr ax,1 ; =sensitivity*min(12,abs(mickeys))/4

shr ax,1

endif

; end_

@@up2ae:

else

jb @@up2ae

mov ax,12

; end_

@@up2ae:

mul dx

if USE_286

shr ax,2 ; =sensitivity*min(12,abs(mickeys))/4

else

shr ax,1 ; =sensitivity*min(12,abs(mickeys))/4

shr ax,1

endif

endif

imul si ; DX:AX=mickeys*newsensitivity

; end_

@@upbe:

add al,byte ptr sensround[bx]

mov byte ptr sensround[bx],al

mov al,ah ; remove 256 multiplier from

mov ah,dl ; sensitivity: AX=DX:AX/256

; adc ax,0 ; add carry from previous adding

db 15h, 0, 0 ; JWASM uses signed byte variant, same length

;----- apply mickeys per 8 pixels ratio to calculate cursor position

@@newmickeys: add word ptr mickeys[bx],ax

if FASTER_CODE

mov si,word ptr mickey8[bx]

cmp si,8

; if_ ne

je @@upeq

if USE_286

shl ax,3

else

shl ax,1

shl ax,1

shl ax,1

endif

dec si

; andif_ gt

jle @@upeq

add ax,word ptr rounderr[bx]

inc si

cwd

idiv si

mov word ptr rounderr[bx],dx

test ax,ax

jz @@uposdone

; end_

@@upeq:

else

if USE_286

shl ax,3

else

shl ax,1

shl ax,1

shl ax,1

endif

add ax,word ptr rounderr[bx]

cwd

idiv word ptr mickey8[bx]

mov word ptr rounderr[bx],dx

endif

add ax,word ptr pos[bx]

;----- cut new position by virtual ranges and save

@savecutpos:: mov dx,word ptr rangemax[bx]

cmp ax,dx

jge @@cutpos

mov dx,word ptr rangemin[bx]

cmp ax,dx

; if_ le

jg @@cpg

@@cutpos: xchg ax,dx ; OPTIMIZE: instead MOV AX,DX

; end_

@@cpg:

mov word ptr pos[bx],ax ; new position

and al,byte ptr granumask[bx]

mov word ptr granpos[bx],ax ; new granulated position

@@uposdone: mov ax,1

@@uposret: ret

updateposition endp

;========================================================================

; In: AL (unrolled press bit mask)

; CL (unrolled buttons change state)

; DL (buttons change state)

; DH (buttons new state)

; BX (buttpress array index)

; Out: CL

; DX (shifted state)

; BX (next index)

; Use: granpos

; Modf: AX, SI, buttpress, buttrelease

;

updatebutton proc

shr dx,1

; if_ carry ; if button changed

jnc @@ubnc

mov si,TSRdref:buttpress

test dl,dl

; if_ ns ; if button not pressed

js @@ubs

add al,al ; indicate that it released

mov si,TSRdref:buttrelease

; end_

@@ubs:

inc word ptr [si + bx + offset BUTTLASTSTATE.counter]

@lastpos:: or cl,al

mov ax,[granpos.Y]

mov [si + bx + offset BUTTLASTSTATE.lastrow],ax

mov ax,[granpos.X]

mov [si + bx + offset BUTTLASTSTATE.lastcol],ax

; end_

@@ubnc:

add bx,size BUTTLASTSTATE ; next button

ret

updatebutton endp

;========================= END OF IRQ HANDLERS ==========================

;============================ INT 10 HANDLER ============================

if USERIL ; -X-

even

RILtable dw TSRcref:RIL_F0 ; RIL functions

dw TSRcref:RIL_F1

dw TSRcref:RIL_F2

dw TSRcref:RIL_F3

dw TSRcref:RIL_F4

dw TSRcref:RIL_F5

dw TSRcref:RIL_F6

dw TSRcref:RIL_F7

endif ; -X- USERIL

int10handler proc

assume ds:nothing,es:nothing

cld

test ah,ah ; set video mode?

jz @@setmode

cmp ah,11h ; font manipulation function

je @@setnewfont

cmp ax,4F02h ; VESA set video mode?

je @@setmode

if USERIL ; -X-

cmp ah,0F0h ; RIL func requested?

jb @@jmpold10

cmp ah,0F7h

jbe @@RIL

cmp ah,0FAh

je @@RIL_FA

endif ; -X- USERIL

@@jmpold10: jmp_far oldint10

@@setnewfont: cmp al,10h

jb @@jmpold10

cmp al,20h

jae @@jmpold10

;j @@setmode

;===== set video mode or activate font

@@setmode: push ax

mov ax,2

pushf ;!!! Logitech MouseWare

push cs ; Windows driver workaround

call handler33 ; hide mouse cursor

pop ax

pushf

call [oldint10]

push ds

push es

PUSHALL

MOVSEG ds,cs,,@TSRdata

mov [nocursorcnt],1 ; normalize hide counter

call setupvideo

@@exitINT10: jmp rethandler

if USERIL ; -X-

;===== RIL

@@RIL: push ds es

PUSHALL

MOVSEG ds,cs,,@TSRdata

mov bp,sp

mov al,ah

and ax,0Fh ;!!! AH must be 0 for RIL_*

mov si,ax

add si,si

call RILtable[si]

j @@exitINT10

;-----

@@RIL_FA: MOVSEG es,cs,,@TSRcode ; RIL FA - Interrogate driver

mov bx,TSRcref:RILversion

else ; -X-

assume ds:nothing ; -X-

assume es:nothing ; -X-

endif ; -X- USERIL

iret

int10handler endp

if USERIL ; -X-

assume ds:@TSRdata

;========================================================================

; RIL F0 - Read one register

;========================================================================

;

; In: DX (group index)

; BX (register #)

; Out: BL (value)

; Use: videoregs@

; Modf: AL, SI

; Call: none

;

RIL_F0 proc