script "revLibURL"

##libUrl v1.2.0 2010-09-16

#

on revLoadLibrary

# MW-2015-01-28: [[ ScriptifyLibURL ]] Use the scriptified stack.

insert the script of stack "revLibUrl" into back

// AL-2015-01-29: [[ Scriptify revLibUrl ]] Initialise custom properties when library is loaded

initialiseCustomProps

end revLoadLibrary

on revUnloadLibrary

remove the script of stack "revLibUrl" from back

end revUnloadLibrary

---------------------------------------------------------------------

##shared locals

local lvCount,lvBlockingUrl,lvBlockBypass,lvAuthBlockBypass,lvLogField, lvTickle

local lvJumpOut ##used by libUrlResetAll to make sure "wait for messages" loops exit cleanly

local laLoadReq,laLoadedUrls,laStatus,laUrl,laLength,laData

local laAction,laUrlLoadStatus,laUrlErrorStatus,laLoadQ, laLoadingUrls

local laUser,laPasswd,laAuth,laBytes,laLongFileName,laHost

local laMessg,laPostData,laTemp

local laCancelled,lvStatusCallback

local laFile,laReadBytes,laWriteBytes

local laConnectHost, laConnectID, laSocketUser

local laUrlFormat

-- MM-2014-02-27: [[ HTTPS Proxy ]] Used to cache the proxy for the given URL (rather than use global httpproxy property)

local laUrlProxy

local lvSocketToken, lvSocketOpenStart, lvSocketOpenMessageID ##for socket opening

local laSocketClosedByScript

-- MM-2014-02-27: [[ HTTPS Proxy ]] Stores if a given socket is secured.

local laSocketSecured

-- MM-2014-02-27: [[ PAC Support ]]

local lvProxyInitialized -- If we have already attempted to extract the systems proxy settings

local lvUsePACFileForProxy -- If we should use the configured PAC file for proxy settings

local lvHTTPProxy -- The proxy server (if any) configured by the system

local lvProxyBypassList -- URLs that bypass any proxy settings

---------------------------------------------------------------------

##http locals

local laConn,laCode,laChunk,laRhHeader, laHaveHeader, laNeedChunk

local laStatusCode, laStatusMessage, laNewLoc

local laLineNum,laTmpData

local laHttpDataDone

local laCurrentHttpHeaders

local laPostLength, laPostBytes

local lvAuthCallbacks, laServerAuthTokens, laProxyAuthTokens

local laMaxPostWithoutExpect

local laAuthRecursCount, lvNewSocketForAuth

local lvSSLVerification, laCurrentSSLVerify

local lvFollowHttpRedirects

-----------------------------------------------------------------------

##ftp locals

local lvFtpMode, lvFtpStopTime, lvDataPortCount, lvFtpListCommand

local laFtpDataDone

local laControlXDataMap ##control sockets keyed by data sockets

local laHome,lvNeedDir

local laControlXLocalMap,laTransPasvIP,laTransActvIP,laMode

local laStopUnit, laStopSec

local laFTPCommandStatus

local lvFtpCommandSocket ##socket used by libUrlFtpCommand

local laUrlByFile ##used by libUrlUploadFile to track which files go to which url

------------------------------------------------

on libraryStack

if the target is not me then pass libraryStack

// AL-2015-01-29: [[ Scriptify revLibUrl ]] Initialise custom properties when stack becomes in use

initialiseCustomProps

end libraryStack

------------------------------------------------

on initialiseCustomProps

# initialise ftp codes prop set

local tFtpCodes

put "ABOR:225,226|Connect:220|CWD:250|DELE:250|LIST:125,150|MKD:257|MODE:200|NLST:125,150|PASS:230,202|PASV:227|PORT:200|PWD:257|QUIT:221|RETR:125,150|RMD:250|SIZE:213|STOR:125,150|transferComplete:226|TYPE:200|USER:230,331" into tFtpCodes

split tFtpCodes by "|" and ":"

set the customProperties["cFtpGoodCodes"] of me to tFtpCodes

# initialise default header

set the cDefaultHeader of me to "METHOD --- HTTP/1.1" & return & "Host:" & return & "User-Agent: "

# initialise version

set the cVersion of me to "1.2.0"

# initalise PAC support javascript

local tPacSupport

put "function isPlainHostName(e){return e.indexOf('.')==-1?true:false}function dnsDomainIs(e,t){var n=e.toLowerCase();var r=t.toLowerCase();var i=n.substring(n.length-r.length,n.length);if(i==r)return true;return false}function localHostOrDomainIs(e,t){var n=e.toLowerCase();var r=t.toLowerCase();return n==r||isPlainHostName(n)&!isPlainHostName(r)?true:false}function isResolvable(e){var t=dnsResolve(e);return typeof t=='string'&&t.length?true:false}function isInNet(e,t,n){var r=dnsResolve(e);if(r){var i=t.split('.');var s=n.split('.');var o=r.split('.');if(i.length==s.length&&s.length==o.length){for(var u=0;u<i.length;u++){if((i[u]&s[u])!=(s[u]&o[u]))return false}return true}}return false}function dnsResolve(e){var t;t=__dnsResolve(e);var n;n=t.split('.');if(n.length==4)return t;return null}function myIpAddress(){var e;e=__myIpAddress();var t;t=e.split('.');if(t.length==4)return e;return null}function dnsDomainLevels(e){var t=e.split('.');return t.length-1}function shExpMatch(e,t){if(typeof e!='string'||typeof t!='string')return false;if(t=='*')return true;if(e==''&&t=='')return true;e=e.toLowerCase();t=t.toLowerCase();var n=e.length;var r=t.split('*');var i=0;for(var s=0;s<r.length;s++){if(r[s]=='')continue;if(i>n)return false;i=e.indexOf(r[s]);if(i==-1)return false;i+=r[s].length;e=e.substring(i,n);n=e.length}s--;if(r[s]==''||e=='')return true;return false}function weekdayRange(e,t,n){var r=new Date;var i='SUNMONTUEWEDTHUFRISAT';e=e.toUpperCase();if(t==undefined)t=e;else t=t.toUpperCase();var s=i.indexOf(e);var o=i.indexOf(t);if(o==-1&&t=='GMT'){n=t;o=s}if(s==-1||o==-1)return false;s=s/3;o=o/3;if(n=='GMT')r=r.getUTCDay();else r=r.getDay();if(s<=o&&r>=s&&r<=o)return true;if(o<s&&(r<=o||r>=s))return true;return false}function dateRange(){var e=new Date;var t=arguments.length;var n=arguments[t-1];if(typeof n!='string')n=false;else{n=n.toUpperCase();if(n!='GMT')n=false;else{n=true;t--}}if(!t||t>6)return false;var r=0;var i=0;var s=0;var o=0;var u=0;var a=0;for(var f=0;f<t;f++){var l=arguments[f];if(typeof l=='number'){if(l>31){if(!u)u=l;else if(!a)a=l;else return false}else if(!l)return false;else if(!r)r=l;else if(!i)i=l;else return false}else if(typeof l=='string'){var c='JANFEBMARAPRMAYJUNJULAUGSEPOCTNOVDEC';l=l.toUpperCase();l=c.indexOf(l);if(l==-1)return false;l/=3;l+=1;if(!s)s=l;else if(!o)o=l;else return false}else return false}if(!u)u=n?e.getUTCFullYear():e.getFullYear();if(!a)a=u;if(!s)s=(n?e.getUTCMonth():e.getMonth())+1;if(!o)o=s;if(!r)r=n?e.getUTCDate():e.getDate();if(!i)i=r;var h;var p;if(n){h=Date.UTC(u,s-1,r,0,0,0,0);p=Date.UTC(a,o-1,i,23,59,59,999)}else{h=Date(u,s-1,r,0,0,0,0).valueOf();p=Date(a,o-1,i,23,59,59,999).valueOf()}e=e.valueOf();return h<=e&&e<=p}function timeRange(){var e=0;var t=new Date;var n=new Date;var r=new Date;var i=arguments.length;var s=arguments[i-1];if(typeof s!='string')s=false;else{s=s.toUpperCase();if(s!='GMT')s=false;else{s=true;i--}}if(!i||i>6||i%2&&i!=1)return false;t.setMinutes(0);t.setSeconds(0);t.setMilliseconds(0);r.setMinutes(59);r.setSeconds(59);r.setMilliseconds(999);for(e=0;e<i/2;e++){var o=arguments[e];if(s){switch(e){case 0:t.setUTCHours(o);r.setUTCHours(o);break;case 1:t.setUTCMinutes(o);r.setUTCMinutes(o);break;case 2:t.setUTCSeconds(o);r.setUTCSeconds(o);break}}else{switch(e){case 0:t.setHours(o);r.setHours(o);break;case 1:t.setMinutes(o);r.setMinutes(o);break;case 2:t.setSeconds(o);r.setSeconds(o);break}}}if(i!=1){r.setMinutes(0);r.setSeconds(0);r.setMilliseconds(0);for(e=0;e<i/2;e++){var o=arguments[i/2+e];if(s){switch(e){case 0:r.setUTCHours(o);break;case 1:r.setUTCMinutes(o);break;case 2:r.setUTCSeconds(o);break}}else{switch(e){case 0:r.setHours(o);break;case 1:r.setMinutes(o);break;case 2:r.setSeconds(o);break}}}}n=n.valueOf();t=t.valueOf();r=r.valueOf();if(r<t)r+=864e5;return t<=n&&n<=r}function __FindProxyForURL(e,t){return FindProxyForURL(e,t)}" into tPacSupport

set the cPACSupport of me to tPacSupport

# initialise top level domains

local tTopLevelDomains

put "biz,com,info,name,net,org,pro,aero,asia,cat,coop,edu,gov,int,jobs,mil,mobi,museum,tel,travel,arpa,nato,example,invalid,localhost,test,bitnet,csnet,local,root,uucp,onion,exit,berlin,lat,nyc,bzh,cym,gal,sco,geo,mail,kids,post,shop,web,xxx,ac,ad,ae,af,ag,ai,al,am,an,ao,aq,ar,as,at,au,aq,ax,az,ac,ad,ae,af,ag,ai,al,am,an,ao,aq,ar,as,at,au,aw,ax,az,ba,bb,bd,be,bf,bg,bh,bi,bj,bm,bn,bo,br,bs,bt,bw,by,bz,ca,cc,cd,cf,cg,ch,ci,ck,cl,cm,cn,co,cr,cu,cv,cx,cy,cz,de,dj,dk,dm,do,dz,ec,ee,eg,er,es,et,eu,fi,fj,fk,fm,fo,fr,ga,gd,ge,gf,gg,gh,gi,gl,gm,gn,gp,gq,gr,gs,gt,gu,gw,gy,hk,hm,hn,hr,ht,hu,id,ie,il,im,in,io,iq,ir,is,it,je,jm,jo,jp,ke,kg,kh,ki,km,kn,kp,kr,kw,ky,kz,la,lb,lc,li,lk,lr,ls,lt,lu,lv,ly,ma,mc,md,me,mg,mh,mk,ml,mm,mn,mo,mp,mq,mr,ms,mt,mu,mv,mw,mx,my,mz,na,nc,ne,nf,ng,ni,nl,no,np,nr,nu,nz,om,pa,pe,pf,pg,ph,pk,pl,pn,pr,ps,pt,pw,py,qa,re,ro,rs,ru,rw,sa,sb,sc,sd,se,sg,sh,si,sk,sl,sm,sn,sr,st,su,sv,sy,sz,tc,td,tf,tg,th,tj,tk,tl,tm,tn,to,tr,tt,tv,tw,tz,ua,ug,uk,us,uy,uz,va,vc,ve,vg,vi,vn,vu,wf,ws,ye,za,zm,zw,um,bl,eh,mf,bv,gb,pm,sj,so,yt,tp,yu,cs,zr" into tTopLevelDomains

replace comma with return in tTopLevelDomains

set the cTopLevelDomains of me to tTopLevelDomains

end initialiseCustomProps

## for debugging ##

function md5 pString

local tHex

get binaryDecode("h*", md5digest(pString), tHex)

return tHex

end md5

##

#######Engine Calls#############################################

####### load url #############################################

------------------------------------------------

on loadUrl x,y

local newUrl

put false into lvJumpOut

put ulStripUrl(x) into newUrl

if lvCount is empty then

put "6923" into lvCount

end if

switch

case newUrl is among the lines of the keys of laLoadingUrls

##don't allow loads if the same url is waiting to load

return "error URL is currently loading" ##with empty

break

case newUrl is not among the lines of the keys of laLoadedUrls OR laUrlLoadStatus[newUrl] is not "cached"

## put the long id of the target &","& item 2 of the params into laMessg[newUrl]

##dc 081104

put the long id of the target &","& item -1 of the params into laMessg[newUrl]

put true into laLoadReq[newUrl]

put 1 into laLoadingUrls[newUrl] #for tracking

put "getData" into laAction[newUrl]

put empty into laUrlErrorStatus[newUrl]

put empty into laUrlLoadStatus[newUrl]

put empty into laLoadedUrls[newUrl]

ulGetFormat newUrl,lvCount

-- SN 2014-02-21 Decode the URL read according to the encoding specified in the head part

ulDecodeData newUrl

if laUrlLoadStatus[newUrl] is "error" and not laCancelled[newurl] then

ulSendMessage newUrl ##send message now only if error occurred befoe block point

return "error"

----------------------

else if laCancelled[newUrl] then

##user cancelled after starting but before blocking point

delete local laLoadedUrls[newUrl]

delete local laUrlLoadStatus[newUrl]

delete local laUrlErrorStatus[newUrl]

delete local laStatus[newUrl]

delete local laCancelled[newUrl]

delete local laCurrentHttpHeaders[newUrl]

else

return empty

end if

-----------------------

break

case newUrl is among the lines of the keys of laLoadedUrls and laUrlLoadStatus[newUrl] is "cached" #url is in cache

## put the long id of the target &","& item 2 of the params into laMessg[newUrl]

##dc 081104

put the long id of the target &","& item -1 of the params into laMessg[newUrl]

ulSendMessage newUrl ##send message

return empty

end switch

end loadUrl

#############unload url############

on unloadUrl pUrl

put ulStripUrl(pUrl) into pUrl

##need to check if it is loading or in loadQ

if pUrl is among the lines of keys(laLoadingUrls) then

delete local laLoadingUrls[pUrl]

ulCancelRequest pUrl ##stop any current downloads

delete local laData[pUrl] ##in case download hasn't started

return empty

else if pUrl is among the lines of keys(laUrlLoadStatus) then

delete local laLoadedUrls[pUrl]

delete local laUrlLoadStatus[pUrl]

delete local laUrlErrorStatus[pUrl]

delete local laStatus[pUrl]

return empty

else ##not loaded

return "can't find url"

end if

end unloadUrl

############# get url ############

on getUrl x

local newUrl,tRetResult,tRetData

put false into lvJumpOut

put ulStripUrl(x) into newUrl

if newUrl is among the lines of the keys of laLoadedUrls and laUrlLoadStatus[newUrl] is "cached" then

if "2.4.1" is in the version then

return empty with laLoadedUrls[newUrl]

else

return empty with cachedUrl laLoadedUrls[newUrl]

end if

end if

if newUrl is among the lines of keys(laLoadingUrls) and (lvAuthBlockBypass is not true) then

return "error URL is currently loading" with empty

end if

if lvBlockingUrl is empty or lvBlockBypass is true or lvAuthBlockBypass is true then

put newUrl into lvBlockingUrl

if lvCount is empty then

put "6923" into lvCount

end if

put empty into laUrlErrorStatus[newUrl]

put "getData" into laAction[newUrl]

put empty into laData[newUrl]

ulGetFormat newUrl,lvCount # convert url to components

-- SN 2014-02-21 Decode the URL read according to the encoding specified in the head part

ulDecodeData newUrl

##final clean up here

if laAuthRecursCount[newUrl] < 1 then

delete local laStatus[newUrl] ##

delete local laAuthRecursCount[newUrl] ##

put laUrlErrorStatus[newUrl] into tRetResult

delete local laUrlErrorStatus[newUrl]

if "2.4.1" is in the version then

##for mc 2.4.1 engine only

put laData[newUrl] into tRetData ##swap data before deleting laData

delete local laData[newUrl]

put empty into lvBlockingUrl ##clear

return tRetResult with tRetData

else

put empty into lvBlockingUrl ##clear

return tRetResult with url laData[newUrl]

end if

else

return 1

end if

else ##blocked by previous request

return "error Previous request not completed" with empty

end if

end getUrl

############### post Url ###################

on postUrl y,x

local newUrl,tRetResult,tRetData

put textEncode(y, "native") into y

put false into lvJumpOut

put ulStripUrl(x) into newUrl

if newUrl is among the lines of keys(laLoadingUrls) then

return "error URL is currently loading" with empty

end if

if lvBlockingUrl is empty or lvBlockBypass or lvAuthBlockBypass is true then

put newUrl into lvBlockingUrl

if lvCount is empty then

put "6923" into lvCount

end if

put y into laPostData[newUrl]

put length(y) into laPostLength[newUrl]

put 0 into laPostBytes[newUrl]

put "postData" into laAction[newUrl]

put empty into laUrlErrorStatus[newUrl]

put empty into laData[newUrl]

ulGetFormat newUrl,lvCount # convert url to components

----------------------------------

##final clean up here

if laAuthRecursCount[newUrl] < 1 then

delete local laStatus[newUrl]

delete local laAuthRecursCount[newUrl]

put laUrlErrorStatus[newUrl] into tRetResult

delete local laUrlErrorStatus[newUrl]

if "2.4.1" is in the version then

##for mc 2.4.1 engine only

put laData[newUrl] into tRetData

delete local laData[newUrl]

put empty into lvBlockingUrl ##clear

return tRetResult with tRetData

else

put empty into lvBlockingUrl ##clear

return tRetResult with url laData[newUrl]

end if

else

return 1

end if

-----------------------------------

else ##blocked by previous request

put "error Previous request not completed" into tRetResult

return tRetResult with empty

end if

end postUrl

############### put x into url ################

on putUrl y,x

local newUrl,tRetResult,tRetData

put textEncode(y, "native") into y

put false into lvJumpOut

put ulStripUrl(x) into newUrl

if newUrl is among the lines of keys(laLoadingUrls) then

return "error URL is currently loading" with empty

end if

if lvBlockingUrl is empty or lvBlockBypass or lvAuthBlockBypass is true then

put newUrl into lvBlockingUrl

if lvCount is empty then

put "6923" into lvCount

end if

put y into laPostData[newUrl]

put length(y) into laPostLength[newUrl]

put 0 into laPostBytes[newUrl]

put "putData" into laAction[newUrl]

put empty into laUrlErrorStatus[newUrl]

put empty into laData[newUrl]

ulGetFormat newUrl,lvCount # convert url to components

----------------------------------

##final clean up here

if laAuthRecursCount[newUrl] < 1 then

delete local laStatus[newUrl]

delete local laAuthRecursCount[newUrl]

put laUrlErrorStatus[newUrl] into tRetResult

delete local laUrlErrorStatus[newUrl]

if "2.4.1" is in the version then

##for mc 2.4.1 engine only

put laData[newUrl] into tRetData

delete local laData[newUrl]

put empty into lvBlockingUrl ##clear

return tRetResult with tRetData

else

put empty into lvBlockingUrl ##clear

return tRetResult with url laData[newUrl]

end if

else

return 1

end if

-----------------------------------

else ##blocked by previous request

put "error Previous request not completed" into tRetResult

return tRetResult with empty

end if

end putUrl

###############delete url########################

on deleteUrl x

local newUrl,tRetResult,tRetData

put false into lvJumpOut

put ulStripUrl(x) into newUrl

if newUrl is among the lines of keys(laLoadingUrls) then

return "error URL is currently loading" with empty

end if

if lvBlockingUrl is empty or lvBlockBypass is true then

put newUrl into lvBlockingUrl

if lvCount is empty then

put "6923" into lvCount

end if

put "deleteData" into laAction[newUrl]

put empty into laUrlErrorStatus[newUrl]

ulGetFormat newUrl,lvCount # convert url to components

----------------------------------

##final clean up here

delete local laStatus[newUrl]

put laUrlErrorStatus[newUrl] into tRetResult

delete local laUrlErrorStatus[newUrl]

if "2.4.1" is in the version then

##for mc 2.4.1 engine only

put laData[newUrl] into tRetData

delete local laData[newUrl]

put empty into lvBlockingUrl ##clear

return tRetResult with tRetData

else

put empty into lvBlockingUrl ##clear

return tRetResult with url laData[newUrl]

end if

-----------------------------------

else ##blocked by previous request

put "error Previous request not completed" into tRetResult

return tRetResult with empty

end if

end deleteUrl

######## cachedUrls ################################################

on getCachedUrls

local tKey,tLoadedKeys,tRes

#ensure url has "cached" status

#there may be urls with data but with "error" status

#for example, with a 404 error, the "courtesy page" may appear in the data

put keys(laUrlLoadStatus) into tLoadedKeys

repeat for each line tKey in tLoadedKeys

if laUrlLoadStatus[tKey] is "cached" then

put tKey & cr after tRes

end if

end repeat

if char -1 of tRes is cr then delete char -1 of tRes

return tRes

end getCachedUrls

######## UrlStatus ###################################################

on getUrlStatus x #x is url

put ulStripUrl(x) into x

return laUrlLoadStatus[x]

end getUrlStatus

####################breaks down the url into components####################

on ulGetFormat pUrl,pCount

local tString,tOff,tURLHost,tUrlPort,tSavedDel

local tConnectHost,tBadAddress

local tPre,tUser,tPass,tHost,tPort,tFilename,tHostblock

try

## url parsing method changed for 1.0.13

## we use offset and not just matchText to keep compatible with older engines

## that can't handle non-greedy regex

put pUrl into tString

put offset("://", tString) into tOff

if tOff > 0 then

put char 1 to tOff -1 of tString into tPre

delete char 1 to tOff + 2 of tString

put offset("/",tString) into tOff

if tOff > 0 then

put char 1 to tOff -1 of tString into tHostblock

put char tOff to -1 of tString into tFilename

else if tOff = 0 and length(tString) > 0 then

put tString into tHostblock

put empty into tFilename

else

throw "error"

end if

else

throw "error"

end if

if matchText(tHostBlock, "(.+):(.+)@([^:]*)(.*)", tUser,tPass,tHost,tPort) then

else if matchText(tHostBlock, "([^:]*)(.*)", tHost,tPort) then

else

throw "error"

end if

if tPort is not empty and char 2 to -1 of tPort is not a integer then

throw "error"

end if

catch pErr

put "invalid URL: " & quote & pUrl & quote into laUrlErrorStatus[pUrl]

if laLoadReq[pUrl] then put "error" into laUrlLoadStatus[pUrl]

exit "ulGetFormat"

end try

if tPre is "https" and char 1 to 3 of the version < 2.6 then

put "https protocol not supported in this version" into laUrlErrorStatus[pUrl]

if laLoadReq[pUrl] then

put "error" into laUrlLoadStatus[pUrl]

delete local laLoadingUrls[pUrl]

end if

exit "ulGetFormat"

end if

##set connection IP

switch tPre

case "http"

case "https"

-- MM-2014-02-27: [[ PAC Support ]] Extract any proxy for the given URL.

put _proxyForURL(pURL) into laUrlProxy[pURL]

ulLogIt "Proxy for URL:" && laUrlProxy[pURL] & cr

-- MM-2014-02-27: [[ HTTPS Proxy ]] We now support fetching https URLs through a proxy.

if laUrlProxy[pURL] is not empty then

## for now don't allow https connections through proxies

## will look at this again later

put tHost into tURLHost

put laUrlProxy[pURL] into tHost

replace "http://" with "" in tHost ##not sure if this is possible but just in case

if tPort <> empty then

put tPort into tUrlPort ##save this for setting laFilename below

else if tPre is "https" then

put ":443" into tUrlPort

else

put ":80" into tUrlPort

end if

#get the proxy port

put the itemdel into tSavedDel

set the itemdel to ":"

if the number of items of tHost > 1 and item -1 of tHost is a number then

put ":" & item -1 of tHost into tPort

delete item -1 of tHost #remove port for now

else

put ":80" into tPort

end if

set the itemDel to tSavedDel

else if tPort is empty then

if tPre is "https" then

put ":443" into tPort

else

put ":80" into tPort

end if

end if

break

case "ftp"

if tFilename is empty then ## require a file or directory path for FTP

put "invalid URL: " & quote & pUrl & quote into laUrlErrorStatus[pUrl]

if laLoadReq[pUrl] then put "error" into laUrlLoadStatus[pUrl]

exit "ulGetFormat"

end if

if tPort is empty then put ":21" into tPort

if tUser is empty then

put "anonymous" into tUser

put "guest" into tPass

end if

break

default

put "invalid URL: " & quote & pUrl & quote into laUrlErrorStatus[pUrl]

if laLoadReq[pUrl] then put "error" into laUrlLoadStatus[pUrl]

exit "ulGetFormat"

break

end switch

if laUrlFormat[pUrl]["references"] > 0 then

add 1 to laUrlFormat[pUrl]["references"]

else

put 1 into laUrlFormat[pUrl]["references"]

put tPre into laUrlFormat[pUrl]["protocol"]

put tHost into laURLFormat[pURL]["host"]

put tPort into laURLFormat[pURL]["port"]

put tUser into laURLFormat[pURL]["user"]

put tPass into laURLFormat[pURL]["pass"]

put tFilename into laURLFormat[pURL]["filename"]

# if using a proxy, these contain the host & port of the requested URL

put tURLPort into laURLFormat[pURL]["urlPort"]

put tURLHost into laURLFormat[pURL]["urlhost"]

end if

##store current state of httpHeaders ad use when request is actually processed

put the httpHeaders into laCurrentHttpHeaders[pURL]

local tResolveHost

put merge("[[tHost]]|[[pURL]]") into tResolveHost

# clear status before resolving hostname

put empty into laStatus[pUrl]

## I.M 2010.03.24 with engine versions < 4.5 calling hostnametoaddress with

## an extra parameter will throw an error, so encase in a try ... catch block

## and call without callback handler

try

get hostNameToAddress(tResolveHost, "ulHostnameToAddressCallback")

catch pError

get hostNameToAddress(tResolveHost)

if the result is empty then ulHostNameToAddressCallback tResolveHost, it

end try

## I.M. 2010-03-11 Need to check result and handle immediate failure where

## no callback message will be sent

if the result is not empty then

ulHostNameToAddressCallback tResolveHost, empty

end if

if laLoadReq[pUrl] is empty or laAuthRecursCount[pUrl] > 0 then ##dc 170205

repeat while laStatus[pUrl] is empty

if lvJumpOut then exit to top

wait for messages

end repeat

end if

end ulGetFormat

################################################################################

on ulHostNameToAddressCallback, pHostname, pIP

local tURL, tOffset

local tPre, tHost, tPort, tUser, tPass, tFilename, tURLHost, tURLPort

local tConnectHost, tBadAddress

put offset("|", pHostname) into tOffset

put char (tOffset + 1) to -1 of pHostname into tURL

put laURLFormat[tURL]["protocol"] into tPre

put laURLFormat[tURL]["host"] into tHost

put laURLFormat[tURL]["port"] into tPort

put laURLFormat[tURL]["user"] into tUser

put laURLFormat[tURL]["pass"] into tPass

put laURLFormat[tURL]["filename"] into tFilename

put laURLFormat[tURL]["urlPort"] into tURLPort

put laURLFormat[tURL]["urlHost"] into tURLHost

if pIP is not empty then

put line 1 of pIP & tPort into tConnectHost

##TEMP CHECK

if tPre is "https" then

put tHost & tPort into tConnectHost

end if

##

else

put true into tBadAddress

end if

if tBadAddress then

put "invalid host address" into laUrlErrorStatus[tURL]

if laLoadReq[tURL] then

put "error" into laUrlLoadStatus[tURL]

delete local laLoadingUrls[tURL]

delete local laAction[tURL]

ulSendMessage tURL

end if

put false into laStatus[tUrl]

##need better clean up here

else

##dc 080702

##need to keep separate reference for ftp IPs by user

## in case we need to connect to two accounts simultaneously

##so just keep user + host ref for all urls

##so laConnectHost has format host:port|user

put tConnectHost & "|" & tUser into laConnectHost[tURL]

if tUser is not empty then put urlDecode(tUser) into laUser[tURL]

if tPass is not empty then

put urlDecode(tPass) into laPasswd[tURL]

put "true" into laAuth[tURL]

end if

put tHost into laHost[tURL]

if tFileName is empty then put "/" into tFileName

-- MM-2014-02-27: [[ HTTPS Proxy ]] We now support fetching HTTPS URLS through a proxy.

if laUrlProxy[tURL] <> empty then

----changed for 1.0.10 Remove username:password from url when sending request through a proxy

if tPre is "http" then

put tPre & "://" & tURLHost & tUrlPort & tFilename into laLongFileName[tURL] ##check later about proxies!!!

else

put tFileName into laLongFileName[tURL]

end if

put tURLHost into laHost[tURL]

else

put tFileName into laLongFileName[tURL]

end if

put "booked" into laUrlErrorStatus[tURL]

if tPre = "http" or tPre = "https" then

if tPre = "https" then

put lvSSLVerification into laCurrentSSLVerify[tURL]

end if

ulHttpRequest tURL

else

ulFtpRequest tURL

end if

end if

## AL-2013-07-30: [[ Bug 10796 ]]  HTTP "get URL" omits port number from HOST header

## delete this array at the end so that 'get url' can use the port and protocol data.

subtract 1 from laURLFormat[tURL]["references"]

if laURLFormat[tURL]["references"] is 0 then

delete local laURLFormat[tURL]

end if

end ulHostNameToAddressCallback

#################choose http method####################

on ulHttpRequest pUrl

switch

case laAction[pUrl] is "getData"

if(laLoadReq[pUrl]) is true and laAuthRecursCount[pUrl] < 1 then

ulHttpLoad pUrl

else

ulGetHttp pUrl

end if

break

case laAction[pUrl] is "deleteData"

ulDeleteHttp pUrl

break

case laAction[pUrl] is "putData"

ulPutHttp pUrl

break

case laAction[pUrl] is "postData"

ulPostHttp pUrl

end switch

end ulHttpRequest

--------------------------------------------------

##set up queue for http load requests

on ulHttpLoad pUrl

local tIP,tLoadingKeys,tHaveConnection

put laConnectHost[pUrl] into tIP

put keys(laLoadQ) into tLoadingKeys

if tIP is among the lines of tLoadingKeys then

put true into tHaveConnection

else

put false into tHaveConnection

end if

put pUrl & cr after laLoadQ[tIP]

put "queued" into laUrlLoadStatus[pUrl]

if not tHaveConnection then

ulNextHttpLoadRequest tIP

end if

end ulHttpLoad

------------------------------------------------

##dispatch next load request

on ulNextHttpLoadRequest pIP

local tUrl

put line 1 of laLoadQ[pIP] into tUrl

if tUrl <> empty then

if tUrl = lvBlockingUrl then ##the same URL is being requested in a blocking call

repeat until lvBlockingUrl <> tUrl

if lvJumpOut then exit to top

wait for messages

end repeat

end if

##in case url was "unloaded" during any wait, check that it's still in the queue

if tUrl is among the lines of keys(laLoadingUrls) then

delete line 1 of laLoadQ[pIP] ##added in 1.0.8r4

ulGetHttp tUrl

else

##modified dc 00202 Delete current rquest if not in laLoadingUrls

-----------------------------------

## CLEAN UP POINT if user cancelled while in queue

delete line 1 of laLoadQ[pIP] ##delete this item

ulCleanUpHttpLocals tUrl

delete local laLoadReq[tUrl] ##added dc 210702

delete local laLoadedUrls[tUrl]##added dc 210702

delete local laMessg[tUrl]##added dc 210702

delete local laUrlErrorStatus[tUrl]

delete local laUrlLoadStatus[tUrl]

delete local laCancelled[tUrl]

if the number of lines of laLoadQ[pIP] = 0 then

delete local laLoadQ[pIP]

delete local laConnectID[pIP]

else

##use send to ensure this thread finishes before next request

send "ulNextHttpLoadRequest" && quote & pIP & quote to me in 1 milliseconds

end if

------------------------------

end if

end if

end ulNextHttpLoadRequest

##############method GET#########################

on ulGetHttp pUrl

local tSocket,tRequest

try

put empty into laStatus[pUrl] ##set wait flag here

put "started" into laUrlErrorStatus[pUrl]

put ulWhichSocket(pUrl) into tSocket

put pUrl into laUrl[tSocket] #ref the url to the used socket##KEY REFERENCE

if tSocket is not among the lines of the openSockets then

ulStartTickle ##safeguard routine

get ulOpenSocket(tSocket)

if not it then throw it ##error opening socket

end if

put "contacted" into laUrlErrorStatus[pUrl]

if laLoadReq[pUrl] then put "contacted" into laUrlLoadStatus[pUrl]

ulSendCallback pUrl,"contacted" ##CALLBACK FEATURE

##ADD file opening HERE for libUrlDownloadToFile

if laFile[pUrl] <> empty then

open file laFile[pUrl] for binary write

if the result is not empty then

throw the result

end if

end if

put ulBuildHttpRequest(pUrl) into tRequest

ulLogit tRequest & cr ##LOG

write tRequest & crlf to socket tSocket with message "ulStartRead"

---------------------

if the result is not empty then

throw the result #early exit

end if

--------------------------

##blocking point "get url"

#If we got here by "load url" then we don't block, otherwise we do

if laLoadReq[pUrl] is empty or laAuthRecursCount[pUrl] > 0 then ##dc 170205

repeat while laStatus[pUrl] is empty

if lvJumpOut then exit to top

wait for messages

end repeat

end if

catch pErr ##clean up point

ulHttpEarlyCleanUp tSocket,pUrl,pErr

exit ulGetHttp

end try

end ulGetHttp

----------------------------------

on ulHttpEarlyCleanUp x, pUrl, pErr

local tLoadReq,tConnectHost

put "error" && pErr into laUrlErrorStatus[pUrl]

if laLoadReq[pUrl] then put "error" into laUrlLoadStatus[pUrl]

put false into laStatus[pUrl] ##to unblock waits

put laLoadReq[pUrl] into tLoadReq ##holder

put laConnectHost[pUrl] into tConnectHost

ulCleanUpHttp x

# OK-2009-03-25 : Bug 7837 - Error code 624 means user interrupt. In this case we unblock and exit to top,

# to allow users to abort loops containing locking url accesses.

if item 1 of pErr = 624 then

put empty into lvBlockingUrl

ulExitToTop

end if

if tLoadReq then

ulSendMessage pUrl ##added 091002

##use send to ensure this thread finishes before next request starts

send "ulNextHttpLoadRequest" && quote & tConnectHost & quote to me in 1 milliseconds

end if

end ulHttpEarlyCleanUp

private command ulExitToTop

exit to top

end ulExitToTop

----------------------------------------------------------

on ulStartRead x,y

local tUrlHolder

if laUrl[x] <> empty then ##carry on

-----------------------------------

put "requested" into laUrlErrorStatus[laUrl[x]]

if laLoadReq[laUrl[x]] then put "requested" into laUrlLoadStatus[laUrl[x]]

ulSendCallback laUrl[x],"requested" ##CALLBACK FEATURE

if laLoadReq[laUrl[x]] then

put empty into laLoadedUrls[laUrl[x]]

else

put empty into laData[laUrl[x]]

end if

put empty into laTmpData[laUrl[x]]

put empty into laTemp[laUrl[x]]

read from socket x with message "ulReadmore"

--------------------------------

if the result <> empty then

put "error" && the result into laUrlErrorStatus[laUrl[x]]

if laLoadReq[laUrl[x]] then put "error" into laUrlLoadStatus[laUrl[x]]

put false into laStatus[laUrl[x]] ##to unblock wait

end if

----------------------------------

##The wait in the getHttp handler allows "load" requests to pass

## we wait here for ALL requests so we can clean up

---------------------------------------

put laUrl[x] into tUrlHolder

repeat while laStatus[tUrlHolder] is empty

if lvJumpOut then exit to top

wait for messages

end repeat

----------------------------------------

## CLEAN UP POINT

####auth handling here

## if not laLoadReq[laUrl[x]] then ##removed to allow load with authcallback

ulHandleAuth x

## end if

if laStatus[laUrl[x]] is false and x is among the lines of the opensockets then

close socket x ##if user unloaded

else if laConn[laUrl[x]] is "close" and x is among the lines of the opensockets then

close socket x ##

end if

if word 1 of laUrlErrorStatus[laUrl[x]] is "error" then

ulSendCallback laUrl[x], "error" ##send CALLBACK here if error

end if

if laAuthRecursCount[laUrl[x]] < 1 then

ulHttpLateCleanUp x

if lvNewSocketForAuth > 0 then

ulRemoveAuthSocketRefs tUrlHolder

end if

end if

end if

end ulStartRead

---------------------------------------

on ulRemoveAuthSocketRefs pUrl

##removes any other socket references to laUrl

##that may have been used in authorisation recursion

## when new sockest were used

put empty into lvNewSocketForAuth

local tKeys

put keys(laUrl) into tKeys

repeat for each line tSocket in tKeys

if laUrl[tSocket] = pUrl then

delete local laUrl[tSocket]

end if

end repeat

end ulRemoveAuthSocketRefs

---------------------------------------------------------------

on ulHandleAuth x

local tSkip,tOff,tAuth,i,tLine,tCloseSocket,tRes, tNewSocketForAuth

if laStatusCode[laUrl[x]] is 407 then ##proxy authentication

put 0 into tSkip

repeat

put lineOffset("Proxy-Authenticate:",laRhHeader[laUrl[x]],tSkip) into tOff

if tOff = 0 then exit repeat

put line (tOff + tSkip) of laRhHeader[laUrl[x]] into tAuth[word 2 of line (tOff + tSkip) of laRhHeader[laUrl[x]]]

add tOff to tSkip

end repeat

repeat with i = the number of lines of lvAuthCallbacks down to 1

put line i of lvAuthCallbacks into tLine

if item 1 of tLine is among the lines of keys(tAuth) then

put laConn[laUrl[x]] is "close" into tCloseSocket ##

add 1 to laAuthRecursCount[laUrl[x]]

if tCloseSocket then

put true into laSocketClosedByScript[x] ##for OS X

close socket x ##

add 1 to lvNewSocketForAuth

end if

ulSendAuthMessage item 1 of tLine, laUrl[x], tAuth[item 1 of tLine]

put the result into tRes

subtract 1 from laAuthRecursCount[laUrl[x]]

exit repeat

end if

end repeat

else if laStatusCode[laUrl[x]] is 401 then ###www-authentication

put 0 into tSkip

repeat

put lineOffset("WWW-Authenticate:",laRhHeader[laUrl[x]],tSkip) into tOff

if tOff = 0 then exit repeat

put line (tOff + tSkip) of laRhHeader[laUrl[x]] into tAuth[word 2 of line (tOff + tSkip) of laRhHeader[laUrl[x]]]

add tOff to tSkip

end repeat

repeat with i = the number of lines of lvAuthCallbacks down to 1

put line i of lvAuthCallbacks into tLine

if item 1 of tLine is among the lines of keys(tAuth) then

put laConn[laUrl[x]] is "close" into tCloseSocket ##

add 1 to laAuthRecursCount[laUrl[x]]

if tCloseSocket then

put true into laSocketClosedByScript[x] ##for OS X

close socket x ##

add 1 to lvNewSocketForAuth

end if

ulSendAuthMessage item 1 of tLine, laUrl[x], tAuth[item 1 of tLine]

put the result into tRes

subtract 1 from laAuthRecursCount[laUrl[x]]

exit repeat

end if

end repeat

end if

end ulHandleAuth

--------------------------------------

on ulParseHeaders x

local tLocLine,tLenLine,tContentLine,tCodeLine,tConnectionLine,ptConnLine

set the lastRhHeaders of me to laRhHeader[laUrl[x]] ##set property

// SN-2015-06-04: [[ Bug 15456 ]] Apply fix proposed by Dave Cragg

// see http://runtime-revolution.278305.n4.nabble.com/OT-More-on-false-timeouts-and-headers-td4692465.html

filter lines of laRhHeader[laUrl[x]] without "*Content-Transfer-Encoding:*"

put lineOffset("Location:",laRhHeader[laUrl[x]]) into tLocLine

put lineOffset("Content-Length:",laRhHeader[laUrl[x]]) into tLenLine

put lineOffset("Content-Type:",laRhHeader[laUrl[x]]) into tContentLine

put lineOffset("Transfer-Encoding:",laRhHeader[laUrl[x]]) into tCodeLine

put lineOffset("Connection:",laRhHeader[laUrl[x]]) into tConnectionLine

put lineOffset("Proxy-Connection:",laRhHeader[laUrl[x]]) into ptConnLine

#get status code

put word 2 of line 1 of laRhHeader[laUrl[x]] into laStatusCode[laUrl[x]]

#get status message for error results

put word 2 to -1 of line 1 of laRhHeader[laUrl[x]] into laStatusMessage[laUrl[x]]

if laStatusCode[laUrl[x]] is not a number then ##no point hanging around

return "Unable to resolve server response."

# put "error" && "Unable to resolve server response." into laUrlErrorStatus[laUrl[x]]

# if laLoadReq[laUrl[x]] then put "error" into laUrlLoadStatus[laUrl[x]]

# put false into laStatus[laUrl[x]] ##to unblock wait

# exit "ulDoProcess"

end if

# MW-2011-04-23: [[ Bug 9520 ]] HTTP headers don't necessarily have a space