forked from nativeformat/NFHTTP
-
Notifications
You must be signed in to change notification settings - Fork 0
Expand file tree
/
Copy pathClientNSURLSession.mm
More file actions
216 lines (188 loc) · 8.59 KB
/
ClientNSURLSession.mm
File metadata and controls
216 lines (188 loc) · 8.59 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
/*
* Copyright (c) 2017 Spotify AB.
*
* Licensed to the Apache Software Foundation (ASF) under one
* or more contributor license agreements. See the NOTICE file
* distributed with this work for additional information
* regarding copyright ownership. The ASF licenses this file
* to you under the Apache License, Version 2.0 (the
* "License"); you may not use this file except in compliance
* with the License. You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing,
* software distributed under the License is distributed on an
* "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
* KIND, either express or implied. See the License for the
* specific language governing permissions and limitations
* under the License.
*/
#if __APPLE__
#include "ClientNSURLSession.h"
#include <NFHTTP/ResponseImplementation.h>
#include <unordered_map>
#include "RequestTokenDelegate.h"
#include "RequestTokenImplementation.h"
#import <Foundation/Foundation.h>
namespace nativeformat {
namespace http {
static NSString *languageHeaderValue();
static NSString *generateLanguageHeaderValue();
class ClientNSURLSession : public Client,
public RequestTokenDelegate,
public std::enable_shared_from_this<ClientNSURLSession> {
public:
ClientNSURLSession();
virtual ~ClientNSURLSession();
// Client
std::shared_ptr<RequestToken> performRequest(
const std::shared_ptr<Request> &request,
std::function<void(const std::shared_ptr<Response> &)> callback) override;
// RequestTokenDelegate
void requestTokenDidCancel(const std::shared_ptr<RequestToken> &request_token) override;
private:
static NSURLRequest *requestFromRequest(const std::shared_ptr<Request> &request);
static const std::shared_ptr<Response> responseFromResponse(NSHTTPURLResponse *response,
const std::shared_ptr<Request> request,
NSData *data);
NSURLSession *_session;
std::unordered_map<std::shared_ptr<RequestToken>, NSURLSessionTask *> _tokens;
std::mutex _tokens_mutex;
};
ClientNSURLSession::ClientNSURLSession()
: _session([NSURLSession sessionWithConfiguration:[NSURLSessionConfiguration defaultSessionConfiguration]])
{
}
ClientNSURLSession::~ClientNSURLSession()
{
std::lock_guard<std::mutex> lock(_tokens_mutex);
for (auto &token_task : _tokens) {
[token_task.second cancel];
}
[_session invalidateAndCancel];
}
std::shared_ptr<RequestToken> ClientNSURLSession::performRequest(
const std::shared_ptr<Request> &request, std::function<void(const std::shared_ptr<Response> &)> callback)
{
@autoreleasepool {
NSURLRequest *urlRequest = requestFromRequest(request);
const std::shared_ptr<Request> copied_request = request;
std::shared_ptr<RequestToken> request_token =
std::make_shared<RequestTokenImplementation>(shared_from_this(), request->hash());
NSURLSessionTask *task =
[_session dataTaskWithRequest:urlRequest
completionHandler:^(NSData *data, NSURLResponse *response, NSError *error) {
{
std::lock_guard<std::mutex> lock(_tokens_mutex);
_tokens.erase(request_token);
}
if ([response isKindOfClass:[NSHTTPURLResponse class]]) {
callback(responseFromResponse((NSHTTPURLResponse *)response, copied_request, data));
} else {
callback(responseFromResponse(nil, copied_request, data));
}
}];
{
std::lock_guard<std::mutex> lock(_tokens_mutex);
_tokens[request_token] = task;
}
[task resume];
return request_token;
}
}
void ClientNSURLSession::requestTokenDidCancel(const std::shared_ptr<RequestToken> &request_token)
{
std::lock_guard<std::mutex> lock(_tokens_mutex);
[_tokens[request_token] cancel];
}
NSURLRequest *ClientNSURLSession::requestFromRequest(const std::shared_ptr<Request> &request)
{
static NSString *const AcceptLanguageHeader = @"Accept-Language";
NSString *urlString = [NSString stringWithUTF8String:request->url().c_str()];
NSURL *url = [NSURL URLWithString:urlString];
NSMutableURLRequest *mutableRequest =
[NSMutableURLRequest requestWithURL:url cachePolicy:NSURLRequestReloadIgnoringCacheData timeoutInterval:30.0];
mutableRequest.HTTPMethod = [NSString stringWithUTF8String:request->method().c_str()];
for (const auto &header : request->headerMap()) {
[mutableRequest addValue:[NSString stringWithUTF8String:header.second.c_str()]
forHTTPHeaderField:[NSString stringWithUTF8String:header.first.c_str()]];
}
size_t data_length = 0;
const unsigned char *data = request->data(data_length);
if (data_length > 0) {
mutableRequest.HTTPBody = [NSData dataWithBytes:data length:data_length];
}
if (!mutableRequest.allHTTPHeaderFields[AcceptLanguageHeader]) {
[mutableRequest setValue:languageHeaderValue() forHTTPHeaderField:AcceptLanguageHeader];
}
return mutableRequest.copy;
}
const std::shared_ptr<Response> ClientNSURLSession::responseFromResponse(NSHTTPURLResponse *response,
const std::shared_ptr<Request> request,
NSData *data)
{
std::shared_ptr<Response> new_response = std::make_shared<ResponseImplementation>(
request, (const unsigned char *)data.bytes, data.length, (StatusCode)response.statusCode, false);
for (NSString *header in response.allHeaderFields.allKeys) {
(*new_response)[header.UTF8String] = [response.allHeaderFields[header] UTF8String];
}
return new_response;
}
// Lifted from
// https://raw.githubusercontent.com/spotify/SPTDataLoader/master/SPTDataLoader/SPTDataLoaderRequest.m
static NSString *generateLanguageHeaderValue()
{
const NSInteger SPTDataLoaderRequestMaximumLanguages = 2;
NSString *const SPTDataLoaderRequestEnglishLanguageValue = @"en";
NSString *const SPTDataLoaderRequestLanguageHeaderValuesJoiner = @", ";
NSString * (^constructLanguageHeaderValue)(NSString *, double) =
^NSString *(NSString *language, double languageImportance)
{
NSString *const SPTDataLoaderRequestLanguageFormatString = @"%@;q=%.2f";
return [NSString stringWithFormat:SPTDataLoaderRequestLanguageFormatString, language, languageImportance];
};
NSArray *languages = [NSBundle mainBundle].preferredLocalizations;
if (languages.count > SPTDataLoaderRequestMaximumLanguages) {
languages = [languages subarrayWithRange:NSMakeRange(0, SPTDataLoaderRequestMaximumLanguages)];
}
double languageImportanceCounter = 1.0;
NSMutableArray *languageHeaderValues = [NSMutableArray arrayWithCapacity:languages.count];
BOOL containsEnglish = NO;
for (NSString *language in languages) {
if (!containsEnglish) {
NSString *const SPTDataLoaderRequestLanguageLocaleSeparator = @"-";
NSString *languageValue =
[language componentsSeparatedByString:SPTDataLoaderRequestLanguageLocaleSeparator].firstObject;
if ([languageValue isEqualToString:SPTDataLoaderRequestEnglishLanguageValue]) {
containsEnglish = YES;
}
}
if (languageImportanceCounter == 1.0) {
[languageHeaderValues addObject:language];
} else {
[languageHeaderValues addObject:constructLanguageHeaderValue(language, languageImportanceCounter)];
}
languageImportanceCounter -= (1.0 / languages.count);
}
if (!containsEnglish) {
[languageHeaderValues addObject:constructLanguageHeaderValue(SPTDataLoaderRequestEnglishLanguageValue, 0.01)];
}
return [languageHeaderValues componentsJoinedByString:SPTDataLoaderRequestLanguageHeaderValuesJoiner];
}
static NSString *languageHeaderValue()
{
static NSString *languageHeaderValue = nil;
static dispatch_once_t onceToken;
dispatch_once(&onceToken, ^{
languageHeaderValue = generateLanguageHeaderValue();
});
return languageHeaderValue;
}
std::shared_ptr<Client> createNSURLSessionClient()
{
return std::make_shared<ClientNSURLSession>();
}
} // namespace http
} // namespace nativeformat
#endif