#define strcasecmp_P(s1, s2) strcasecmp((s1), (s2))

#include "ArduinoEasy-Globals.h"

#include "Misc.h"

String webdata = "";

class DummyWebServer

{

public:

String arg(String name); // get request argument value by name

protected:

};

String DummyWebServer::arg(String arg)

{

#ifdef DEBUG_WEB2

Serial.print("webdata3:");

Serial.println(webdata);

#endif

arg = "&" + arg;

#ifdef DEBUG_WEB2

Serial.print("arg:");

Serial.println(arg);

#endif

String returnarg = "";

int pos = webdata.indexOf(arg);

if (pos >= 0)

{

returnarg = webdata.substring(pos+1,pos+81); // max field content 80 ?

pos = returnarg.indexOf("&");

if (pos > 0)

returnarg = returnarg.substring(0, pos);

pos = returnarg.indexOf("=");

if (pos > 0)

returnarg = returnarg.substring(pos + 1);

}

return returnarg;

}

DummyWebServer WebServer;

void WebServerHandleClient() {

EthernetClient client = MyWebServer.available();

if (client) {

// an http request ends with a blank line

boolean currentLineIsBlank = true;

String request = "";

boolean getrequest = true;

webdata = "";

webdata.reserve(500);

while (client.connected()) {

if (client.available()) {

char c = client.read();

if (getrequest)

request += c;

#ifdef DEBUG_WEB

Serial.write(c);

#endif

// if you've gotten to the end of the line (received a newline

// character) and the line is blank, the http request has ended,

// so you can send a reply

if (c == '\n' && currentLineIsBlank) {

// request is known here, in case of 'rules' we could handle this smarter (save index+6)?

while (client.available()) { // post data...

char c = client.read();

webdata += c;

}

if (webdata.length() !=0)

webdata = "&" + webdata;

#ifdef DEBUG_WEB

Serial.print("webdata0:");

Serial.println(webdata);

Serial.print("len:");

Serial.println(webdata.length());

#endif

int pos = request.indexOf("/");

if (pos > 0)

request = request.substring(pos + 1);

pos = request.indexOf(" ");

if (pos > 0)

request = request.substring(0, pos);

pos = request.indexOf("?");

if (pos >= 0)

{

String args = request.substring(pos + 1);

webdata += "&" + args;

request = request.substring(0, pos);

}

webdata = URLDecode(webdata.c_str());

#ifdef DEBUG_WEB

Serial.print("webdata1:");

Serial.println(webdata);

#endif

if (request.startsWith(F(" HTTP")) or request.length() == 0) // root page

{

addHeader(true, client);

handle_root(client, webdata);

}

else if (request.equals(F("control")))

{

handle_control(client, webdata);

}

else if (request.equals(F("config")))

{

addHeader(true, client);

handle_config(client, webdata);

}

else if (request.equals(F("hardware")))

{

addHeader(true, client);

handle_hardware(client, webdata);

}

else if (request.equals(F("devices")))

{

addHeader(true, client);

handle_devices(client, webdata);

}

else if (request.equals(F("rules")))

{

addHeader(true, client);

handle_rules(client, webdata);

}

else if (request.equals(F("tools")))

{

addHeader(true, client);

handle_tools(client, webdata);

}

else if (request.equals(F("advanced")))

{

addHeader(true, client);

handle_advanced(client, webdata);

}

else if (request.equals(F("SDfilelist")))

{

addHeader(true, client);

handle_SDfilelist(client, webdata);

}

else if (request.equals(F("i2cscanner")))

{

addHeader(true, client);

handle_i2cscanner(client, webdata);

}

else if (request.equals(F("log")))

{

addHeader(true, client);

handle_log(client, webdata);

}

else if (request.equals(F("sysinfo")))

{

addHeader(true, client);

handle_sysinfo(client, webdata);

}

else

handle_unknown(client, request);

break;

}

if (c == '\n') {

// you're starting a new line

currentLineIsBlank = true;

getrequest = false;

} else if (c != '\r') {

// you've gotten a character on the current line

currentLineIsBlank = false;

}

}

}

// give the web browser time to receive the data delay(1);

client.stop();

webdata = "";

}

}

//********************************************************************************

// Add top menu

//********************************************************************************

void addHeader(boolean showMenu, EthernetClient client)

{

client.println(F("HTTP/1.1 200 OK"));

client.println(F("Content-Type: text/html"));

client.println(F("Connection: close")); // the connection will be closed after completion of the response

client.println();

String str = "";

boolean cssfile = false;

str += F("<script language=\"javascript\"><!--\n");

str += F("function dept_onchange(frmselect) {frmselect.submit();}\n");

str += F("//--></script>");

str += F("<head><title>");

str += Settings.Name;

str += F("</title>");

if (!cssfile)

{

str += F("<style>");

str += F("* {font-family:sans-serif; font-size:12pt;}");

str += F("h1 {font-size:16pt; color:black;}");

str += F("h6 {font-size:10pt; color:black; text-align:center;}");

str += F(".button-menu {background-color:#ffffff; color:blue; margin: 10px; text-decoration:none}");

str += F(".button-link {margin:4px; padding:4px 16px; background-color:#07D; color:#FFF; text-decoration:none; border-radius:4px}");

str += F(".button-menu:hover {background:#ddddff;}");

str += F(".button-link:hover {background:#369;}");

str += F("th {padding:10px; background-color:black; color:#ffffff;}");

str += F("td {padding:7px;}");

str += F("table {color:black;}");

str += F(".div_l {float: left;}");

str += F(".div_r {float: right; margin: 2px; padding: 1px 10px; border-radius: 7px; background-color:#080; color:white;}");

str += F(".div_br {clear: both;}");

str += F("</style>");

}

else

str += F("<link rel=\"stylesheet\" type=\"text/css\" href=\"esp.css\">");

str += F("</head>");

str += F("<h1>Welcome to Arduino Easy: ");

str += Settings.Name;

str += F("</h1>");

if (showMenu)

{

str += F("<BR><a class=\"button-menu\" href=\".\">Main</a>");

str += F("<a class=\"button-menu\" href=\"config\">Config</a>");

str += F("<a class=\"button-menu\" href=\"hardware\">Hardware</a>");

str += F("<a class=\"button-menu\" href=\"devices\">Devices</a>");

if (Settings.UseRules)

str += F("<a class=\"button-menu\" href=\"rules\">Rules</a>");

str += F("<a class=\"button-menu\" href=\"tools\">Tools</a><BR><BR>");

}

client.print(str);

}

//********************************************************************************

// Add footer to web page

//********************************************************************************

void addFooter(String& str)

{

str += F("<h6>Powered by www.letscontrolit.com</h6></body>");

}

//********************************************************************************

// Web Interface root page

//********************************************************************************

void handle_root(EthernetClient client, String &post) {

//if (!isLoggedIn()) return;

String sCommand = WebServer.arg(F("cmd"));

if (strcasecmp_P(sCommand.c_str(), PSTR("reboot")) != 0)

{

String reply = "";

reply.reserve(1000);

printToWeb = true;

printWebString = "";

if (sCommand.length() > 0)

ExecuteCommand(VALUE_SOURCE_HTTP, sCommand.c_str());

IPAddress ip = Ethernet.localIP();

IPAddress gw = Ethernet.gatewayIP();

reply += printWebString;

reply += F("<form><table>");

reply += F("<TH>System Info<TH>Value<TH><TH>System Info<TH>Value<TH>");

reply += F("<TR><TD>Unit:<TD>");

reply += Settings.Unit;

reply += F("<TD><TD>Build:<TD>");

reply += BUILD;

reply += F(" ");

reply += F(BUILD_NOTES);

reply += F("<TR><TD>System Time:<TD>");

if (Settings.UseNTP)

{

reply += hour();

reply += F(":");

if (minute() < 10)

reply += F("0");

reply += minute();

}

else

reply += F("NTP Disabled");

reply += F("<TD><TD>Uptime:<TD>");

char strUpTime[40];

int minutes = wdcounter / 2;

int days = minutes / 1440;

minutes = minutes % 1440;

int hrs = minutes / 60;

minutes = minutes % 60;

sprintf_P(strUpTime, PSTR("%d days %d hours %d minutes"), days, hrs, minutes);

reply += strUpTime;

reply += F("<TR><TD>Load:<TD>");

if (wdcounter > 0)

{

reply += 100 - (100 * loopCounterLast / loopCounterMax);

reply += F("% (LC=");

reply += int(loopCounterLast / 30);

reply += F(")");

}

reply += F("<TD><TD>Free Mem:<TD>");

reply += freeMem;

char str[20];

sprintf_P(str, PSTR("%u.%u.%u.%u"), ip[0], ip[1], ip[2], ip[3]);

reply += F("<TR><TD>IP:<TD>");

reply += str;

sprintf_P(str, PSTR("%u.%u.%u.%u"), gw[0], gw[1], gw[2], gw[3]);

reply += F("<TD><TD>GW:<TD>");

reply += str;

client.print(reply);

reply = "";

#if FEATURE_UDP

reply += F("<TR><TH>Node List:<TH>Name<TH>Build<TH>Type<TH>IP<TH>Age");

for (byte x = 0; x < UNIT_MAX; x++)

{

if (Nodes[x].ip[0] != 0)

{

char url[80];

sprintf_P(url, PSTR("<a class='button-link' href='http://%u.%u.%u.%u'>%u.%u.%u.%u</a>"), Nodes[x].ip[0], Nodes[x].ip[1], Nodes[x].ip[2], Nodes[x].ip[3], Nodes[x].ip[0], Nodes[x].ip[1], Nodes[x].ip[2], Nodes[x].ip[3]);

reply += F("<TR><TD>Unit ");

reply += x;

reply += F("<TD>");

#if FEATURE_NODELIST_NAMES

if (x != Settings.Unit)

reply += Nodes[x].nodeName;

else

reply += Settings.Name;

#endif

reply += F("<TD>");

if (Nodes[x].build)

reply += Nodes[x].build;

reply += F("<TD>");

if (Nodes[x].nodeType)

switch (Nodes[x].nodeType)

{

case NODE_TYPE_ID_ESP_EASY_STD:

reply += F("ESP Easy");

break;

case NODE_TYPE_ID_ESP_EASYM_STD:

reply += F("ESP Easy Mega");

break;

case NODE_TYPE_ID_ESP_EASY32_STD:

reply += F("ESP Easy 32");

break;

case NODE_TYPE_ID_ARDUINO_EASY_STD:

reply += F("Arduino Easy");

break;

case NODE_TYPE_ID_NANO_EASY_STD:

reply += F("Nano Easy");

break;

case NODE_TYPE_ID_RPI_EASY_STD:

reply += F("RPI Easy");

break;

}

reply += F("<TD>");

reply += url;

reply += F("<TD>");

reply += Nodes[x].age;

client.print(reply);

reply = "";

}

}

#endif

reply += F("</table></form>");

addFooter(reply);

client.print(reply);

printWebString = "";

printToWeb = false;

}

else

{

// have to disconnect or reboot from within the main loop

// because the webconnection is still active at this point

// disconnect here could result into a crash/reboot...

if (strcasecmp_P(sCommand.c_str(), PSTR("reboot")) == 0)

{

String log = F(" : Rebooting...");

addLog(LOG_LEVEL_INFO, log);

cmd_within_mainloop = CMD_REBOOT;

}

client.print("ok");

}

}

//********************************************************************************

// Web Interface config page

//********************************************************************************

void handle_config(EthernetClient client, String &post) {

//if (!isLoggedIn()) return;

update_config();

webdata = "";

String reply = "";

reply.reserve(500);

reply += F("<form name='frmselect' method='post'><table>");

reply += F("<TH>Main Settings<TH><TR><TD>Name:<TD><input type='text' name='name' value='");

Settings.Name[25] = 0;

reply += Settings.Name;

reply += F("'><TR><TD>Admin Password:<TD><input type='text' name='password' value='");

SecuritySettings.Password[25] = 0;

reply += SecuritySettings.Password;

reply += F("'><TR><TD>Unit nr:<TD><input type='text' name='unit' value='");

reply += Settings.Unit;

client.print(reply);

reply = "";

reply += F("'><TR><TD>Protocol:");

byte choice = Settings.Protocol;

reply += F("<TD><select name='protocol' LANGUAGE=javascript onchange=\"return dept_onchange(frmselect)\" >");

reply += F("<option value='0'>- Standalone -</option>");

for (byte x = 0; x <= protocolCount; x++)

{

reply += F("<option value='");

reply += Protocol[x].Number;

reply += F("'");

if (choice == Protocol[x].Number)

reply += F(" selected");

reply += F(">");

String ProtocolName = "";

CPlugin_ptr[x](CPLUGIN_GET_DEVICENAME, 0, ProtocolName);

reply += ProtocolName;

reply += F("</option>");

}

reply += F("</select>");

reply += F("<a class=\"button-link\" href=\"http://www.letscontrolit.com/wiki/index.php/EasyProtocols\" target=\"_blank\">?</a>");

client.print(reply);

reply = "";

char str[20];

if (Settings.Protocol)

{

byte choice = Settings.UseDNS;

String options[2];

options[0] = F("Use IP address");

options[1] = F("Use Hostname");

int optionValues[2];

optionValues[0] = 0;

optionValues[1] = 1;

reply += F("<TR><TD>Locate Controller:<TD><select name='usedns' LANGUAGE=javascript onchange=\"return dept_onchange(frmselect)\" >");

for (byte x = 0; x < 2; x++)

{

reply += F("<option value='");

reply += optionValues[x];

reply += F("'");

if (choice == optionValues[x])

reply += F(" selected");

reply += F(">");

reply += options[x];

reply += F("</option>");

}

reply += F("</select>");

client.print(reply);

reply = "";

if (Settings.UseDNS)

{

reply += F("<TR><TD>Controller Hostname:<TD><input type='text' name='controllerhostname' size='64' value='");

reply += Settings.ControllerHostName;

}

else

{

reply += F("<TR><TD>Controller IP:<TD><input type='text' name='controllerip' value='");

sprintf_P(str, PSTR("%u.%u.%u.%u"), Settings.Controller_IP[0], Settings.Controller_IP[1], Settings.Controller_IP[2], Settings.Controller_IP[3]);

reply += str;

}

reply += F("'><TR><TD>Controller Port:<TD><input type='text' name='controllerport' value='");

reply += Settings.ControllerPort;

byte ProtocolIndex = getProtocolIndex(Settings.Protocol);

if (Protocol[ProtocolIndex].usesAccount)

{

reply += F("'><TR><TD>Controller User:<TD><input type='text' name='controlleruser' value='");

reply += SecuritySettings.ControllerUser;

}

client.print(reply);

reply = "";

if (Protocol[ProtocolIndex].usesPassword)

{

reply += F("'><TR><TD>Controller Password:<TD><input type='text' name='controllerpassword' value='");

reply += SecuritySettings.ControllerPassword;

}

reply += F("'>");

CPlugin_ptr[ProtocolIndex](CPLUGIN_WEBFORM_LOAD, 0, reply);

}

client.print(reply);

reply = "";

reply += F("<TR><TD>Sensor Delay:<TD><input type='text' name='delay' value='");

reply += Settings.Delay;

reply += F("'>");

reply += F("<TR><TH>Optional Settings<TH>");

reply += F("<TR><TD>IP:<TD><input type='text' name='espip' value='");

sprintf_P(str, PSTR("%u.%u.%u.%u"), Settings.IP[0], Settings.IP[1], Settings.IP[2], Settings.IP[3]);

reply += str;

reply += F("'><TR><TD>GW:<TD><input type='text' name='espgateway' value='");

sprintf_P(str, PSTR("%u.%u.%u.%u"), Settings.Gateway[0], Settings.Gateway[1], Settings.Gateway[2], Settings.Gateway[3]);

reply += str;

reply += F("'><TR><TD>Subnet:<TD><input type='text' name='espsubnet' value='");

sprintf_P(str, PSTR("%u.%u.%u.%u"), Settings.Subnet[0], Settings.Subnet[1], Settings.Subnet[2], Settings.Subnet[3]);

reply += str;

client.print(reply);

reply = "";

reply += F("'><TR><TD>DNS:<TD><input type='text' name='espdns' value='");

sprintf_P(str, PSTR("%u.%u.%u.%u"), Settings.DNS[0], Settings.DNS[1], Settings.DNS[2], Settings.DNS[3]);

reply += str;

reply += F("'><TR><TD><TD><input class=\"button-link\" type='submit' value='Submit'>");

reply += F("</table></form>");

addFooter(reply);

client.print(reply);

}

void update_config()

{

char tmpString[64];

#ifdef DEBUG_WEB

Serial.print("webdata2:");

Serial.println(webdata);

#endif

String arg = "";

arg = WebServer.arg(F("name"));

#ifdef DEBUG_WEB

Serial.print("name:");

Serial.println(arg);

#endif

if (arg[0] != 0)

{

strncpy(Settings.Name, arg.c_str(), sizeof(Settings.Name));

arg = WebServer.arg(F("password"));

strncpy(SecuritySettings.Password, arg.c_str(), sizeof(SecuritySettings.Password));

arg = WebServer.arg(F("protocol"));

if (Settings.Protocol != arg.toInt())

{

Settings.Protocol = arg.toInt();

byte ProtocolIndex = getProtocolIndex(Settings.Protocol);

Settings.ControllerPort = Protocol[ProtocolIndex].defaultPort;

if (Protocol[ProtocolIndex].usesTemplate)

CPlugin_ptr[ProtocolIndex](CPLUGIN_PROTOCOL_TEMPLATE, 0, dummyString);

}

else

{

if (Settings.Protocol != 0)

{

byte ProtocolIndex = getProtocolIndex(Settings.Protocol);

CPlugin_ptr[ProtocolIndex](CPLUGIN_WEBFORM_SAVE, 0, dummyString);

arg = WebServer.arg(F("usedns"));

Settings.UseDNS = arg.toInt();

if (Settings.UseDNS)

{

arg = WebServer.arg(F("controllerhostname"));

strncpy(Settings.ControllerHostName, arg.c_str(), sizeof(Settings.ControllerHostName));

getIPfromHostName();

}

else

{

arg = WebServer.arg(F("controllerip"));

if (arg.length() != 0)

{

arg.toCharArray(tmpString, 26);

str2ip(tmpString, Settings.Controller_IP);

}

}

arg = WebServer.arg(F("controllerport"));

Settings.ControllerPort = arg.toInt();

arg = WebServer.arg(F("controlleruser"));

strncpy(SecuritySettings.ControllerUser, arg.c_str(), sizeof(SecuritySettings.ControllerUser));

arg = WebServer.arg(F("controllerpassword"));

strncpy(SecuritySettings.ControllerPassword, arg.c_str(), sizeof(SecuritySettings.ControllerPassword));

}

}

arg = WebServer.arg(F("delay"));

Settings.Delay = arg.toInt();

arg = WebServer.arg(F("espip"));

arg.toCharArray(tmpString, 26);

str2ip(tmpString, Settings.IP);

arg = WebServer.arg(F("espgateway"));

arg.toCharArray(tmpString, 26);

str2ip(tmpString, Settings.Gateway);

arg = WebServer.arg(F("espsubnet"));

arg.toCharArray(tmpString, 26);

str2ip(tmpString, Settings.Subnet);

arg = WebServer.arg(F("espdns"));

arg.toCharArray(tmpString, 26);

str2ip(tmpString, Settings.DNS);

arg = WebServer.arg(F("unit"));

Settings.Unit = arg.toInt();

SaveSettings();

}

}

//********************************************************************************

// Web Interface hardware page

//********************************************************************************

void handle_hardware(EthernetClient client, String &post) {

//if (!isLoggedIn()) return;

String edit = WebServer.arg(F("edit"));

if (edit.length() != 0)

{

#ifdef STM32_F1 // STM32 F1 detected

#ifndef STM32_OFFICIAL

Settings.PinBootStates[0] = WebServer.arg(F("p0")).toInt();

Settings.PinBootStates[1] = WebServer.arg(F("p1")).toInt();

Settings.PinBootStates[2] = WebServer.arg(F("p2")).toInt();

Settings.PinBootStates[3] = WebServer.arg(F("p3")).toInt();

Settings.PinBootStates[8] = WebServer.arg(F("p8")).toInt();

Settings.PinBootStates[9] = WebServer.arg(F("p9")).toInt();

Settings.PinBootStates[10] = WebServer.arg(F("p10")).toInt();

Settings.PinBootStates[13] = WebServer.arg(F("p13")).toInt();

Settings.PinBootStates[14] = WebServer.arg(F("p14")).toInt();

Settings.PinBootStates[15] = WebServer.arg(F("p15")).toInt();

Settings.PinBootStates[16] = WebServer.arg(F("p16")).toInt();

#else

Settings.PinBootStates[0] = WebServer.arg(F("p0")).toInt();

Settings.PinBootStates[1] = WebServer.arg(F("p1")).toInt();

Settings.PinBootStates[2] = WebServer.arg(F("p2")).toInt();

Settings.PinBootStates[3] = WebServer.arg(F("p3")).toInt();

Settings.PinBootStates[4] = WebServer.arg(F("p4")).toInt();

Settings.PinBootStates[5] = WebServer.arg(F("p5")).toInt();

Settings.PinBootStates[6] = WebServer.arg(F("p6")).toInt();

Settings.PinBootStates[7] = WebServer.arg(F("p7")).toInt();

Settings.PinBootStates[8] = WebServer.arg(F("p8")).toInt();

Settings.PinBootStates[9] = WebServer.arg(F("p9")).toInt();

Settings.PinBootStates[10] = WebServer.arg(F("p10")).toInt();

Settings.PinBootStates[11] = WebServer.arg(F("p11")).toInt();

Settings.PinBootStates[12] = WebServer.arg(F("p12")).toInt();

Settings.PinBootStates[13] = WebServer.arg(F("p13")).toInt();

Settings.PinBootStates[14] = WebServer.arg(F("p14")).toInt();

#endif

#else

Settings.PinBootStates[2] = WebServer.arg(F("p2")).toInt();

Settings.PinBootStates[3] = WebServer.arg(F("p3")).toInt();

Settings.PinBootStates[5] = WebServer.arg(F("p5")).toInt();

Settings.PinBootStates[6] = WebServer.arg(F("p6")).toInt();

Settings.PinBootStates[7] = WebServer.arg(F("p7")).toInt();

Settings.PinBootStates[8] = WebServer.arg(F("p8")).toInt();

Settings.PinBootStates[9] = WebServer.arg(F("p9")).toInt();

Settings.PinBootStates[11] = WebServer.arg(F("p11")).toInt();

Settings.PinBootStates[12] = WebServer.arg(F("p12")).toInt();

#endif

SaveSettings();

}

String reply = "";

reply.reserve(1000);

reply += F("<form method='post'><table><TH>Hardware Settings<TH><TR><TD>");

reply += F("<TR><TD>GPIO boot states:<TD>");

#ifdef STM32_F1 // STM32 F1 detected

#ifndef STM32_OFFICIAL

reply += F("<TR><TD>PA0:<TD>");

addPinStateSelect(reply, "p0", Settings.PinBootStates[0]);

reply += F("<TR><TD>PA1:<TD>");

addPinStateSelect(reply, "p1", Settings.PinBootStates[1]);

reply += F("<TR><TD>PA2:<TD>");

addPinStateSelect(reply, "p2", Settings.PinBootStates[2]);

client.print(reply);

reply = "";

reply += F("<TR><TD>PA3:<TD>");

addPinStateSelect(reply, "p3", Settings.PinBootStates[3]);

reply += F("<TR><TD>PA8:<TD>");

addPinStateSelect(reply, "p8", Settings.PinBootStates[8]);

reply += F("<TR><TD>PA9:<TD>");

addPinStateSelect(reply, "p9", Settings.PinBootStates[9]);

client.print(reply);

reply = "";

reply += F("<TR><TD>PA10:<TD>");

addPinStateSelect(reply, "p10", Settings.PinBootStates[10]);

reply += F("<TR><TD>PA13:<TD>");

addPinStateSelect(reply, "p13", Settings.PinBootStates[13]);

reply += F("<TR><TD>PA14:<TD>");

addPinStateSelect(reply, "p14", Settings.PinBootStates[14]);

client.print(reply);

reply = "";

reply += F("<TR><TD>PA15:<TD>");

addPinStateSelect(reply, "p15", Settings.PinBootStates[15]);

reply += F("<TR><TD>PB0:<TD>");

addPinStateSelect(reply, "p16", Settings.PinBootStates[16]);

#else

reply += F("<TR><TD>PB11:<TD>");

addPinStateSelect(reply, "p0", Settings.PinBootStates[0]);

reply += F("<TR><TD>PB10:<TD>");

addPinStateSelect(reply, "p1", Settings.PinBootStates[1]);

reply += F("<TR><TD>PB2:<TD>");

addPinStateSelect(reply, "p2", Settings.PinBootStates[2]);

client.print(reply);

reply = "";

reply += F("<TR><TD>PB0:<TD>");

addPinStateSelect(reply, "p3", Settings.PinBootStates[3]);

reply += F("<TR><TD>PA7:<TD>");

addPinStateSelect(reply, "p4", Settings.PinBootStates[8]);

reply += F("<TR><TD>PA6:<TD>");

addPinStateSelect(reply, "p5", Settings.PinBootStates[9]);

client.print(reply);

reply = "";

reply += F("<TR><TD>PA5:<TD>");

addPinStateSelect(reply, "p6", Settings.PinBootStates[3]);

reply += F("<TR><TD>PA4:<TD>");

addPinStateSelect(reply, "p7", Settings.PinBootStates[8]);

reply += F("<TR><TD>PA3:<TD>");

addPinStateSelect(reply, "p8", Settings.PinBootStates[9]);

reply += F("<TR><TD>PA2:<TD>");

addPinStateSelect(reply, "p9", Settings.PinBootStates[9]);

client.print(reply);

reply = "";

reply += F("<TR><TD>PA1:<TD>");

addPinStateSelect(reply, "p10", Settings.PinBootStates[10]);

reply += F("<TR><TD>PA0:<TD>");

addPinStateSelect(reply, "p11", Settings.PinBootStates[13]);

reply += F("<TR><TD>PC15:<TD>");

addPinStateSelect(reply, "p12", Settings.PinBootStates[13]);

reply += F("<TR><TD>PC14:<TD>");

addPinStateSelect(reply, "p13", Settings.PinBootStates[13]);

reply += F("<TR><TD>PC13:<TD>");

addPinStateSelect(reply, "p14", Settings.PinBootStates[14]);

client.print(reply);

#endif

#else

reply += F("<TR><TD>D2:<TD>");

addPinStateSelect(reply, "p2", Settings.PinBootStates[2]);

reply += F("<TR><TD>D3:<TD>");

addPinStateSelect(reply, "p3", Settings.PinBootStates[3]);

reply += F("<TR><TD>D5:<TD>");

addPinStateSelect(reply, "p5", Settings.PinBootStates[5]);

client.print(reply);

reply = "";

reply += F("<TR><TD>D6:<TD>");

addPinStateSelect(reply, "p6", Settings.PinBootStates[6]);

reply += F("<TR><TD>D7:<TD>");

addPinStateSelect(reply, "p7", Settings.PinBootStates[7]);

client.print(reply);

reply = "";

reply += F("<TR><TD>D8:<TD>");

addPinStateSelect(reply, "p8", Settings.PinBootStates[8]);

reply += F("<TR><TD>D9:<TD>");

addPinStateSelect(reply, "p9", Settings.PinBootStates[9]);

reply += F("<TR><TD>D11:<TD>");

addPinStateSelect(reply, "p11", Settings.PinBootStates[11]);

client.print(reply);

reply = "";

reply += F("<TR><TD>D12:<TD>");

addPinStateSelect(reply, "p12", Settings.PinBootStates[12]);

#endif

reply += F("<input type='hidden' name='edit' value='1'>");

reply += F("<TR><TD><TD><input class=\"button-link\" type='submit' value='Submit'><TR><TD>");

reply += F("</table></form>");

client.print(reply);

}

//********************************************************************************

// Add a GPIO pin select dropdown list

//********************************************************************************

void addPinStateSelect(String& str, String name, int choice)

{

String options[6];

options[0] = F("Default");

options[1] = F("Output Low");

options[2] = F("Output High");

options[3] = F("Input");

options[4] = F("Input Pulldown");

options[5] = F("Input Pullup");

int optionValues[6];

optionValues[0] = 0;

optionValues[1] = 1;

optionValues[2] = 2;

optionValues[3] = 3;

optionValues[4] = 4;

optionValues[5] = 5;

str += F("<select name='");

str += name;

str += F("'>");

for (byte x = 0; x < 6; x++)

{

str += F("<option value='");

str += optionValues[x];

str += F("'");

if (choice == optionValues[x])

str += F(" selected");

str += F(">");

str += options[x];

str += F("</option>");

}

str += F("</select>");

}

//********************************************************************************

// Web Interface device page

//********************************************************************************

void handle_devices(EthernetClient client, String &post) {

//if (!isLoggedIn()) return;

update_device();

struct EventStruct TempEvent;

String taskindex = WebServer.arg(F("index"));

byte index = taskindex.toInt();

byte page = WebServer.arg(F("page")).toInt();

if (page == 0)

page = 1;

byte setpage = WebServer.arg(F("setpage")).toInt();

if (setpage > 0)

{

if (setpage <= (TASKS_MAX / 4))

page = setpage;

else

page = TASKS_MAX / 4;

}

byte DeviceIndex = 0;

webdata = "";

String reply = "";

reply.reserve(1000);

// show all tasks as table

if (index == 0)

{

reply += F("<table cellpadding='4' border='1' frame='box' rules='all'><TH>");

reply += F("<a class=\"button-link\" href=\"devices?setpage=");

if (page > 1)

reply += page - 1;

else

reply += page;

reply += F("\"><</a>");

reply += F("<a class=\"button-link\" href=\"devices?setpage=");

if (page < (TASKS_MAX / 4))

reply += page + 1;

else

reply += page;

reply += F("\">></a>");

reply += F("<TH>Task<TH>Device<TH>Name<TH>Port<TH>IDX/Variable<TH>GPIO<TH>Values");

String deviceName;

for (byte x = (page - 1) * 4; x < ((page) * 4); x++)

{

reply += F("<TR><TD>");

reply += F("<a class=\"button-link\" href=\"devices?index=");

reply += x + 1;

reply += F("&page=");

reply += page;

reply += F("\">Edit</a>");

reply += F("<TD>");

reply += x + 1;

reply += F("<TD>");

if (Settings.TaskDeviceNumber[x] != 0)

{

LoadTaskSettings(x);

DeviceIndex = getDeviceIndex(Settings.TaskDeviceNumber[x]);

TempEvent.TaskIndex = x;

deviceName = "";

if (Settings.TaskDeviceNumber[x] != 0)

Plugin_ptr[DeviceIndex](PLUGIN_GET_DEVICENAME, &TempEvent, deviceName);

reply += deviceName;

reply += F("<TD>");

reply += ExtraTaskSettings.TaskDeviceName;

reply += F("<TD>");

byte customConfig = false;

customConfig = PluginCall(PLUGIN_WEBFORM_SHOW_CONFIG, &TempEvent, reply);

if (!customConfig)

if (Device[DeviceIndex].Ports != 0)

reply += Settings.TaskDevicePort[x];

reply += F("<TD>");

if (Settings.TaskDeviceID[x] != 0)

reply += Settings.TaskDeviceID[x];

reply += F("<TD>");

if (Settings.TaskDeviceDataFeed[x] == 0)

{

if (Device[DeviceIndex].Type == DEVICE_TYPE_I2C)

{

#ifdef STM32_F1 // STM32 F1 detected

reply += F("PB6");

reply += F("<BR>PB7");

#else

reply += F("GPIO-20");

reply += F("<BR>GPIO-21");

#endif

}

if (Device[DeviceIndex].Type == DEVICE_TYPE_ANALOG)

{

reply += F("A");

reply += Settings.TaskDevicePort[x];

}

if (Settings.TaskDevicePin1[x] != -1)

{

reply += F("GPIO-");

reply += Settings.TaskDevicePin1[x];

}

if (Settings.TaskDevicePin2[x] != -1)

{

reply += F("<BR>GPIO-");

reply += Settings.TaskDevicePin2[x];

}

if (Settings.TaskDevicePin3[x] != -1)

{

reply += F("<BR>GPIO-");

reply += Settings.TaskDevicePin3[x];

}

}

reply += F("<TD>");

byte customValues = false;

customValues = PluginCall(PLUGIN_WEBFORM_SHOW_VALUES, &TempEvent, reply);

if (!customValues)

{

if (Device[DeviceIndex].VType == SENSOR_TYPE_LONG)

{

reply += F("<div class=\"div_l\">");

reply += ExtraTaskSettings.TaskDeviceValueNames[0];

reply += F(":</div><div class=\"div_r\">");

reply += (unsigned long)UserVar[x * VARS_PER_TASK] + ((unsigned long)UserVar[x * VARS_PER_TASK + 1] << 16);

reply += F("</div>");

}

else

{