script "home"

constant kImportantTextColor = "#569e54"

on startup

revSetTestEnvironment($TRAVIS is true)

-- MW-2011-03-13: Make sure the externals are empty on startup

set the externals of me to empty

set the allowInterrupts to false

set the cREVLaunching of me to true

revInternal__Log "Start"

revInternal__Log "Enter", "Startup"

try

revInternal__SetupLicense

revInternal__SetupPaths

revInternal__SetupFolders

revInternal__SetupStackFiles

revInternal__SetupSplash

revInternal__SetupPreferences

revInternal__SetupCustomizationPath

revInternal__SetupExternals

catch tError

revInternal__Log "Error", tError

end try

revInternal__Log "Leave", "Startup"

return tError

end startup

on relaunch

global gREVDevelopment

if gREVDevelopment then

pass relaunch

end if

-- Pass the relaunch request through a hook

local tParameters

repeat with x = 1 to the paramCount

put param(x) into tParameters[x]

end repeat

dispatch command "revHookLaunchInstance" to me with tParameters

if it is "handled" then

if the result is empty then

pass relaunch

else if the result is "background" then

return "background"

end if

return empty

end if

-- The hook did nothing, so do our default processing

repeat with x = 1 to the paramcount

local tStackFile

put param(x) into tStackFile

if there is a file tStackFile then -- open it

revIDEOpenStack tStackFile

else

next repeat

end if

end repeat

end relaunch

on shutdown

if "__revInternal_SavePreferences" is in the pendingMessages then

__revInternal_SavePreferences

end if

end shutdown

on saveStackRequest

set the cantModify of me to true

pass saveStackRequest

end saveStackRequest

on preOpenStack

local tEdition, tSplashPath

if the short name of the owner of the target is not "Home" then

pass preOpenStack

end if

revInternal__Log "Enter", "Pre-Open Stack"

revInternal__InitialiseDefaults

revInternal__Log "Leave", "Pre-Open Stack"

end preOpenStack

on openStack

if the short name of the owner of the target is not "Home" then

pass openStack

end if

revInternal__Log "Enter", "Open Stack"

//send "revInternal__openStack" to me in 0 millisecs

revInternal__openStack

revInternal__Log "Leave", "Open Stack"

end openStack

local sSplashStartTime

on revInternal__openStack

revInternal__Log "Enter", "revInternal__openStack"

put the milliseconds into sSplashStartTime

set the cREVLaunching of stack "Home" to true

local tSuccess

put true into tSuccess

try

if tSuccess then

revInternal__setSplashStatus "Checking System Parameters..."

revInternal__InitialiseSystem

put the result into tSuccess

end if

if tSuccess then

revInternal__setSplashStatus "Loading Libraries..."

revInternal__InitialiseLibraries

put the result into tSuccess

end if

if tSuccess then

revInternal__setSplashStatus "Setting Globals..."

revInternal__InitialiseGlobals

put the result into tSuccess

end if

if tSuccess then

revInternal__setSplashStatus "Setting Preferences..."

revInternal__InitialiseOptions

put the result into tSuccess

end if

if tSuccess then

revInternal__setSplashStatus "Loading Standard Icons..."

set the visible of stack "revGeneralIcons" to false

put true into tSuccess

end if

if tSuccess then

revInternal__setSplashStatus "Loading theme data..."

revInternal__InitialiseIcons

put the result into tSuccess

end if

if tSuccess then

revInternal__setSplashStatus "Loading Patterns..."

repeat for each item tPatternStack in "revGeneralPatterns,revCompatibilityPatterns1,revCompatibilityPatterns2"

get there is a stack tPatternStack

end repeat

put true into tSuccess

end if

if tSuccess then

revInternal__setSplashStatus "Loading Script Editor..."

revInternal__InitialiseScriptEditor

put the result into tSuccess

end if

if tSuccess then

revInternal__setSplashStatus "Loading User Icon Libraries..."

revInternal__InitialiseUserLibraries

put the result into tSuccess

end if

if tSuccess then

revInternal__setSplashStatus "Loading Error Management..."

revInternal__InitialiseErrors

put the result into tSuccess

end if

if tSuccess then

revInternal__setSplashStatus "Loading Menu Bar..."

revInternal__InitialiseMenus

put the result into tSuccess

end if

if tSuccess then

revInternal__setSplashStatus "Loading Tools..."

revInternal__InitialiseTools

put the result into tSuccess

end if

if tSuccess then

revInternal__setSplashStatus "Loading Project Browser..."

revInternal__InitialiseProjectBrowser

put the result into tSuccess

end if

if tSuccess then

revInternal__setSplashStatus "Loading Message Box..."

revInternal__InitialiseMessageBox

put the result into tSuccess

end if

if tSuccess then

revInternal__setSplashStatus "Loading Plug-ins..."

revInternal__InitialisePlugIns

put the result into tSuccess

set the defaultStack to "home" -- plug ins may take away default stack

end if

if tSuccess then

revInternal__setSplashStatus "Cleaning Cache"

revInternal__CleanDocsCache

put the result into tSuccess

end if

if tSuccess and not revEnvironmentIsInstalled() then

revInternal__setSplashStatus "Building Dictionary"

revInternal__BuildDictionary

put the result into tSuccess

end if

if tSuccess then

revInternal__setSplashStatus "Performing Final Steps..."

revInternal__setSplashStatus ""

revInternal__InitialiseFinalSteps

put the result into tSuccess

end if

catch tError

revInternal__Log "Error", tError

end try

set the cREVLaunching of stack "Home" to false

if not tSuccess then

quit

end if

if $REV_TOOLS_PATH is empty and (revInternal__CheckFileAssociations() is true) and (the platform is "win32") then

if revIDEGetPreference("cDontShowFileAssociationsDialog") is not true then

modal stack "revFileAssociations"

end if

end if

# AL-2015-07-10: Temporarily disable welcome screen

/*

if revIDEGetPreference("welcomeScreenShown") is not "true" then

revIDEOpenPalette "Welcome"

else if revIDEPrefGet("StartPageShow") is not "false" then

*/

if revIDEGetPreference("cStartPageShow") is not "false" then

revIDEOpenPalette "Start Center"

end if

-- MM-2011-09-27: The new auto update process is handled entirely by the installer.

-- Luanch the installer in update mode to begin update process.

--

if line 3 of revLicenseInfo is not "evaluation" then

local tCommand, tOldPath

put $PATH into tOldPath

set the itemdelimiter to "/"

switch the platform

case "MacOS"

put item 1 to -5 of the filename me & "/Contents/MacOS/autoupdater" into tCommand

put quote & tCommand & quote && "install -update" into tCommand

break

case "Win32"

put item 1 to -3 of the filename me & "/.setup.exe" into tCommand

put quote & tCommand & quote && "install -update" into tCommand

break

case "Linux"

-- MDW-2015-12-19 [[fix_installer]] LC8-style setup filename

if the processor is "x86_64" then

put item 1 to -3 of the filename me & "/setup.x86_64" into tCommand

else

put item 1 to -3 of the filename me & "/setup.x86" into tCommand

end if

put tCommand && "install -update" into tCommand

break

end switch

set the itemDel to comma

open process tCommand for neither

put tOldPath into $PATH

end if

close stack "revSplash"

revInternal__Log "Leave", "revInternal__openStack"

revInternal__Log "End"

-- Now the home stack has loaded, we can allow interrupts..

set the allowInterrupts to true

end revInternal__openStack

on revInternal__setSplashStatus pMessage

revInternal__Log "Message", pMessage

set the statusMessage of stack "revSplash" to pMessage

end revInternal__setSplashStatus

local sLicensePlatform

local sLicenseClass

local sLicenseVersion

local sLicenseName

local sLicenseOrganization

local sLicenseMultiplicity

-- This is the path to the folder containing the IDE's folders

local sToolsPath

-- This is the path to the folder containing user preferences

local sPreferencesPath

-- This is the path to the folder containing user support files

local sCrashLogPath

local sCachePath

-- This is the path to the user-specified IDE customization folder

local sCustomizationPath

-- This is the path to the folder containing per-user dictionary data

local sUserDocsPath

-- This is the path to the folder containing user preferences for the IDE prior to 4.5

local sOldPreferencesPath

-- This is the path to the folder containing support files for the IDE prior to 4.5

local sOldSupportPath

-- MW-2013-06-10: [[ CloneAndRun ]] This is the path containing all the binaries the IDE should

-- use. If empty it means use default installed locations, otherwise this is a git repo build

local sBinariesPath

-- MW-2013-06-10: [[ CloneAndRun ]] This is the path containing the root of the git repository.

local sRepositoryPath

//EJB

local sOverrideRuntimePath, sTestEnvironment

-- Parameterize this so it makes it easier to change.

constant kProductName = "LiveCode"

--------------------------------------------------------------------------------

-- Internal Setup Functions

--

private command revInternal__SetupLicense

revInternal__Log "Enter", "License Setup"

put line 1 of the revLicenseInfo into sLicenseName

put line 2 of the revLicenseInfo into sLicenseOrganization

put line 3 of the revLicenseInfo into sLicenseClass

put line 4 of the revLicenseInfo into sLicenseMultiplicity

if sLicenseMultiplicity is empty then

put 1 into sLicenseMultiplicity

end if

put the version && "build" && the buildnumber into sLicenseVersion

put revEnvironmentPlatform() into sLicensePlatform

revInternal__Log "Leave", "License Setup"

end revInternal__SetupLicense

private command revInternal__SetupPaths

revInternal__Log "Enter", "Path Setup"

local tHomePath

put the filename of me into tHomePath

set the itemDelimiter to "/"

put item 1 to -3 of tHomePath into sToolsPath

-- MW-2013-06-13: Extract the engine path from 'the address' (needs adjustment

-- per platform).

local tEnginePath

set the itemDelimiter to ":"

put item 2 to -1 of the address into tEnginePath

set the itemDelimiter to "/"

switch revEnvironmentPlatform()

case "Linux"

local tOldFolder

put the folder into tOldFolder

set the folder to "~"

put the folder & slash & ".runrev/revolution/enterprise/preferences" into sOldPreferencesPath

if there is no folder sOldPreferencesPath then

put the folder & slash & ".runrev/revolution/studio/preferences" into sOldPreferencesPath

end if

if there is no folder sOldPreferencesPath then

put the folder & slash & ".runrev/revolution/media/preferences" into sOldPreferencesPath

end if

put the folder & slash & ".runrev/preferences" into sPreferencesPath

put the folder & slash & ".runrev/cache" into sCachePath

put the folder & slash & ".runrev/crashlogs" into sCrashLogPath

put the folder & slash & ".runrev/documentationcache" into sUserDocsPath

set the folder to tOldFolder

-- MW-2013-06-13: Adjust the engine path for Linux

put item 1 to -2 of tEnginePath into tEnginePath

break

case "MacOS X"

put specialFolderPath("Preferences") & "/Runtime Revolution/Revolution Enterprise" into sOldPreferencesPath

if there is no folder sOldPreferencesPath then

put specialFolderPath("Preferences") & "/Runtime Revolution/Revolution Studio" into sOldPreferencesPath

end if

if there is no folder sOldPreferencesPath then

put specialFolderPath("Preferences") & "/Runtime Revolution/Revolution Media" into sOldPreferencesPath

end if

put specialFolderPath("Preferences") & "/RunRev" into sPreferencesPath

put specialFolderPath("cusr") & "/Library/Application Support/RunRev/Cache" into sCachePath

put specialFolderPath("cusr") & "/Library/Application Support/RunRev/Crash Logs" into sCrashLogPath

put specialFolderPath("cusr") & "/Library/Application Support/RunRev/Documentation Cache" into sUserDocsPath

-- MW-2013-06-13: Adjust the engine path for Mac

put item 1 to -5 of tEnginePath into tEnginePath

break

case "Windows"

-- We put prefereces into the 'Roaming' AppData folder.

put specialFolderPath(0x001a) & "/Runtime Revolution/Revolution Enterprise/Preferences" into sOldPreferencesPath

if there is no folder sOldPreferencesPath then

put specialFolderPath(0x001a) & "/Runtime Revolution/Revolution Studio/Preferences" into sOldPreferencesPath

end if

if there is no folder sOldPreferencesPath then

put specialFolderPath(0x001a) & "/Runtime Revolution/Revolution Media/Preferences" into sOldPreferencesPath

end if

put specialFolderPath(0x001a) & "/RunRev/Preferences" into sPreferencesPath

-- We put everything else in the 'Local' AppData folder.

put specialFolderPath(0x001c) & "/RunRev/Cache" into sCachePath

put specialFolderPath(0x001c) & "/RunRev/Crash Logs" into sCrashLogPath

put specialFolderPath(0x001c) & "/RunRev/Documentation Cache" into sUserDocsPath

-- MW-2013-06-13: Adjust the engine path for Windows

put item 1 to -2 of tEnginePath into tEnginePath

break

end switch

# The docs cache is per-version and edition

local tEdition

put tolower(sLicenseClass) into tEdition

local tVersion

put the version into tVersion

put replaceText(tVersion, "[-,\.]", "_") into tVersion

put slash & tVersion & "_" & tEdition after sUserDocsPath

-- MW-2013-06-13: [[ CloneAndRun ]] Set up the binaries path.

local tRepositoryPath

put revEnvironmentGuessRepositoryPath(tEnginePath) into tRepositoryPath

if tRepositoryPath is not empty then

put tRepositoryPath into sRepositoryPath

put tEnginePath into sBinariesPath

global gRevDevelopment

put true into gRevDevelopment

global gRevPopups

put true into gRevPopups

else

put empty into sRepositoryPath

end if

revInternal__Log "Message", "Tools Path = " & sToolsPath

revInternal__Log "Message", "Old Preferences Path = " & sOldPreferencesPath

revInternal__Log "Message", "Preferences Path = " & sPreferencesPath

revInternal__Log "Message", "Cache Path = " & sCachePath

revInternal__Log "Message", "Crash Log Path = " & sCrashLogPath

revInternal__Log "Message", "Binaries Path = " & sBinariesPath

revInternal__Log "Leave", "Path Setup"

end revInternal__SetupPaths

command revInternal__SetupCustomizationPath

revInternal__Log "Enter", "Customization Path Setup"

# If there is a customization path set in the preferences, and it exists, then use it, otherwise

# revert to old behavior.

local tUserCustomizationPath

put the cCustomizationPath of stack "revPreferences" into tUserCustomizationPath

if tUserCustomizationPath is not empty then

put tUserCustomizationPath into sCustomizationPath

else

switch revEnvironmentPlatform()

case "Linux"

local tOldFolder

put the folder into tOldFolder

set the folder to "~"

put the folder & slash & "my_livecode" into sCustomizationPath

set the folder to tOldFolder

break

case "Windows"

put specialFolderPath(0x0005) & "/My LiveCode" into sCustomizationPath

break

case "MacOS X"

put specialFolderPath("docs") & "/My LiveCode" into sCustomizationPath

break

end switch

revInternal__Log "Message", "Customization Path = " & sCustomizationPath

end if

revInternal__Log "Leave", "Customization Path Setup"

end revInternal__SetupCustomizationPath

function revInternal__StackFiles

local tPaletteFolder, tFolders

put revEnvironmentToolsetPath() & slash & "palettes" into tPaletteFolder

put tPaletteFolder into tFolders

repeat for each line tFolder in folders(tPaletteFolder)

if char 1 of tFolder is "." then next repeat

put return & tPaletteFolder & slash & tFolder after tFolders

end repeat

put return & revEnvironmentToolsetPath() & slash & "libraries" after tFolders

if not revEnvironmentIsInstalled() then

put return & revEnvironmentRepositoryPath() & slash & "ide-support" after tFolders

-- legacy from commercial repo

put return & revEnvironmentCommercialRepositoryPath() & "/ide/Toolset/libraries" after tFolders

put revEnvironmentCommercialRepositoryPath() & "/ide/Toolset/palettes" into tPaletteFolder

repeat for each line tFolder in folders(tPaletteFolder)

if tFolder begins with "." then next repeat

put return & tPaletteFolder & slash & tFolder after tFolders

end repeat

-- components

local tComponentFolder

put revEnvironmentCommercialRepositoryPath() & "/components" into tComponentFolder

repeat for each line tFolder in folders(tComponentFolder)

if tFolder begins with "." then next repeat

put return & tComponentFolder & slash & tFolder after tFolders

end repeat

-- commercial extensions (ensure they are loaded from the repo)

local tExtensionFolder

put revEnvironmentCommercialRepositoryPath() & "/extensions/script-libraries" into tExtensionFolder

repeat for each line tFolder in folders(tExtensionFolder)

if tFolder begins with "." then next repeat

put return & tExtensionFolder & slash & tFolder after tFolders

end repeat

-- extensions (ensure they are loaded from the repo)

put revEnvironmentRepositoryPath() & "/extensions/script-libraries" into tExtensionFolder

repeat for each line tFolder in folders(tExtensionFolder)

if tFolder begins with "." then next repeat

put return & tExtensionFolder & slash & tFolder after tFolders

end repeat

end if

local tStackFiles, tStackName

local tStackFilesA, tIDEVersion

set the itemdel to "."

put item 1 of the version into tIDEVersion

repeat for each line tPath in tFolders

repeat for each line tFile in files(tPath)

if the last item of tFile is not among the items of "rev.livecode.livecodescript" then next repeat

put item 1 to -2 of tFile into tStackName

local tVersion

put empty into tVersion

// AL-2015-02-18: [[ Named Stack Versions ]] Check if this stack should be loaded in this version.

if not (tFile begins with "revidelibrary") and the number of items in tFile > 2 then

get item -2 of tFile

if it is a number then

put it into tVersion

put item 1 to -3 of tFile into tStackName

if tVersion > tIDEVersion then

next repeat

end if

end if

end if

if tStackName is "revpreferences" then next repeat

// AL-2015-02-18: [[ Named Stack Versions ]] Choose a versioned stack file name over an unversioned one, and a later version over an earlier one.

local tExistingVersion

put tStackFilesA[tStackName]["version"] into tExistingVersion

if tExistingVersion is empty or tVersion > tExistingVersion then

put tPath & slash & tFile into tStackFilesA[tStackName]["file"]

put tVersion into tStackFilesA[tStackName]["version"]

end if

end repeat

end repeat

lock messages

repeat for each key tKey in tStackFilesA

try

put the short name of stack tStackFilesA[tKey]["file"] into tStackName

delete stack tStackName

put tStackName & comma & tStackFilesA[tKey]["file"] & return after tStackFiles

catch e

revInternal__Log "Error", "Could not load stack:" && tStackFilesA[tKey]["file"]

end try

end repeat

unlock messages

delete the last char of tStackFiles

return tStackFiles

end revInternal__StackFiles

private command revInternal__SetupPreferences

revInternal__Log "Enter", "Preferences Setup"

local tOldPreferencesStackFile, tOldNewPreferencesStackFile

put sOldPreferencesPath & "/revpreferences.rev" into tOldPreferencesStackFile

put sPreferencesPath & "/reventerprise.rev" into tOldNewPreferencesStackFile

local tPreferencesStackFile

put sPreferencesPath & "/" & toLower(kProductName) & ".rev" into tPreferencesStackFile

local tPreferencesStackFile7

put sPreferencesPath & "/" & toLower(kProductName) & "7.rev" into tPreferencesStackFile7

local tIndex, tStackFiles

-- First check to see if we have a preferences stack file in the new location that

-- will not load.

if there is a file tPreferencesStackFile7 and there is no stack tPreferencesStackFile7 then

revInternal__Log "Message", "Existing Preferences 7 Stack Corrupted"

put 1 into tIndex

repeat while there is a file (tPreferencesStackFile7 & ".corrupt." & tIndex)

add 1 to tIndex

end repeat

revInternal__Log "Message", "Moving Broken Stack to '" & tPreferencesStackFile7 & "'"

rename file tPreferencesStackFile7 to (tPreferencesStackFile7 & ".corrupt." & tIndex)

end if

-- Next check to see that if there is a preferences file in the old location, if there

-- there is no preferences stackfile in the new location.

if there is no file tPreferencesStackFile7 and there is a file tPreferencesStackFile then

revInternal__Log "Message", "Found 2.7 preferences file, copying to new location."

put url ("binfile:" & tPreferencesStackFile) into url ("binfile:" & tPreferencesStackFile7)

end if

if there is no file tPreferencesStackFile7 and there is a file tOldNewPreferencesStackFile then

revInternal__Log "Message", "Found preferences in new location with old name, copying to new location."

-- MM-2012-05-03: Fixed typo - changed tOldPreferencesStackFile to tOldNewPreferencesStackFile

put url ("binfile:" & tOldNewPreferencesStackFile) into url ("binfile:" & tPreferencesStackFile7)

end if

-- Next check to see if there is a preferences file in the new location under the

-- name 'reventerprise'.

if there is no file tPreferencesStackFile7 and there is a file tOldNewPreferencesStackFile then

revInternal__Log "Message", "Found preferences in new location with old name, copying to new location."

-- MM-2012-05-03: Fixed typo - changed tOldPreferencesStackFile to tOldNewPreferencesStackFile

put url ("binfile:" & tOldNewPreferencesStackFile) into url ("binfile:" & tPreferencesStackFile7)

end if

if there is no file tPreferencesStackFile7 then

revInternal__Log "Message", "No Existing Preferences Stack Found"

revInternal__Log "Message", "Copying template preferences to '" & tPreferencesStackFile7 & "'"

lock messages

if there is not a stack "revpreferences" then

create invisible stack "revpreferences"

end if

set the filename of stack "revpreferences" to tPreferencesStackFile7

revInternal__ResetPreferences

unlock messages

end if

-- ensure the script of stack preferences is empty

-- as setprops could be dangerous

set the script of stack tPreferencesStackFile7 to empty

put the stackFiles of stack "Home" into tStackFiles

put return & "revPreferences", tPreferencesStackFile7 after tStackFiles

set the stackFiles of stack "Home" to tStackFiles

revInternal__Log "Message", "Mapping Stack 'revpreferences.rev' to stackfile '" & tPreferencesStackFile7 & "'"

revInternal__Log "Leave", "Preferences Setup"

end revInternal__SetupPreferences

private command revInternal__SetupFolders

revInternal__Log "Enter", "Folders Setup"

local tPath, tComponent

set the itemDelimiter to "/"

revInternal__Log "Message", "Setting up Preferences Path"

revInternal__EnsureFolder sPreferencesPath

revInternal__Log "Message", "Setting up Cache Path"

revInternal__EnsureFolder sCachePath

revInternal__Log "Message", "Setting up Crash Log Path"

revInternal__EnsureFolder sCrashLogPath

revInternal__Log "Message", "Setting up Docs Path"

revInternal__EnsureFolder sUserDocsPath

revInternal__Log "Leave", "Folders Setup"

end revInternal__SetupFolders

private command revInternal__SetupSplash

palette stack "revSplash"

end revInternal__SetupSplash

command revInternal__ResetPreferences

-- clear the preferences stack

set the customKeys of stack "revPreferences" to empty

set the customPropertySets of stack "revPreferences" to empty

local tPropsArray

-- default custom property set

put "true" into tPropsArray["cREVToolsPaintToolsVisible"]

put "false" into tPropsArray["cDestroyStack"]

put "false" into tPropsArray["cRevPopups"]

put "417,113" into tPropsArray["cREVMsgTabRectGlobalProperties"]

put "155" into tPropsArray["cREVPlayerWidth"]

put "23" into tPropsArray["cButtonHeight"]

put "true" into tPropsArray["cShowProfileEditor"]

put "200" into tPropsArray["cScrollbarwidth"]

put "false" into tPropsArray["cREVMsgShowUIMessages"]

put "false" into tPropsArray["cSEHidePalettes"]

put "120" into tPropsArray["cREVImageWidth"]

put "500" into tPropsArray["tooltip delay"]

put "417,72" into tPropsArray["cREVMsgTabRectSingle Line"]

put "false" into tPropsArray["cREVMsgShowUIBackScripts"]

put "539,432" into tPropsArray["cREVGeoTopLeft"]

put "70378" into tPropsArray["cREVDBCode"]

put "276" into tPropsArray["cREVScriptHeight"]

put "2" into tPropsArray["cGridSize"]

put "483,214,1015,476" into tPropsArray["cVariableWatcherRect"]

put "false" into tPropsArray["cShowrevProps"]

put "Pixels" into tPropsArray["cREVRulerMeasurement"]

put "100" into tPropsArray["cMacOSScrollbarWidth"]

put "1,2,3,4,5,7" into tPropsArray["cControlTabs"]

put "500" into tPropsArray["cREVToolTipDelay"]

put "250" into tPropsArray["cTabButtonwidth"]

put "true" into tPropsArray["cGoAlign"]

put "0" into tPropsArray["cREVRotatePrev2"]

put "993,712" into tPropsArray["cREVPropertyPaletteTopLeft"]

put "true" into tPropsArray["cLiveColor"]

put "modification date" into tPropsArray["cRecentSort"]

put "true" into tPropsArray["cDocsFirstRun"]

put "86400" into tPropsArray["cUpdate,MaxAutoPopupFrequency"]

put "true" into tPropsArray["cREVExtension"]

put "102" into tPropsArray["cMenuWidth"]

put "417,72" into tPropsArray["cREVMsgTabRectcard id 1147"]

put "468,131" into tPropsArray["cAppearanceTopLeft"]

put "false" into tPropsArray["cREVDefaultMenubar"]

put "417,113" into tPropsArray["cREVMsgTabRectbackScripts"]

put "true" into tPropsArray["cGrid"]

put "30" into tPropsArray["cNumRecent"]

put "false" into tPropsArray["cShowAsHandlers"]

put "false" into tPropsArray["revDocsAlreadySeen"]

put "120" into tPropsArray["cREVImageHeight"]

put "82" into tPropsArray["cButtonWidth"]

put "true" into tPropsArray["cREVProfileReadOnlyWarning"]

put "6,7,9" into tPropsArray["cCardTabs"]

put "16" into tPropsArray["cMacOSScrollbarHeight"]

put "true" into tPropsArray["cFirstRun"]

put "14" into tPropsArray["cMacOSProgressScrollbarHeight"]

put "mouseMove" into tPropsArray["suppressedMessages"]

put "true" into tPropsArray["cAutoFormat"]

put "true" into tPropsArray["cREVScriptShortcut"]

put "false" into tPropsArray["cShowRevolutionStacks"]

put "22" into tPropsArray["cMenuHeight"]

put "1067,251,1882,827" into tPropsArray["cRevDocsRect"]

put "Gray88" into tPropsArray["cBackDropColor"]

put "Gray88" into tPropsArray["cBackdrop"]

put "false" into tPropsArray["cREVMsgShowUIFrontScripts"]

put "false" into tPropsArray["revstack"]

put "100" into tPropsArray["cMacOSProgressScrollbarWidth"]

put "false" into tPropsArray["cREVUIScriptShortcut"]

put "60,27" into tPropsArray["cREVMenuBarTopLeft"]

put "322" into tPropsArray["cREVFieldFirstTabHeight"]

put "500" into tPropsArray["cTraceDelay"]

put "0" into tPropsArray["cREVRotatePrev1"]

put "250" into tPropsArray["cFieldWidth"]

put "16" into tPropsArray["cScrollbarHeight"]

put "true" into tPropsArray["cToolbarIcons"]

put "true" into tPropsArray["cShowAudioclipsclips"]

put "1,2,3,4,5" into tPropsArray["cAudioclipTabs"]

put "620,235" into tPropsArray["cREVMsgTabRectSingleLine"]

put "Sections List" into tPropsArray["revHelpDefaultSection"]

put "false" into tPropsArray["cCaseSensitive"]

put "auto" into tPropsArray["cLargeFonts"]

put "Yellow" into tPropsArray["yellow"]

put "417,113" into tPropsArray["cREVMsgTabRectGlobalVariables"]

put "417,113" into tPropsArray["cREVMsgTabRectpendingMessages"]

put "Property Inspector" into tPropsArray["cABCommandDoubleClick"]

put "1" into tPropsArray["cREVTipNumber"]

put "417,113" into tPropsArray["cREVMsgTabRectstacksInUse"]

put format("blue\nbrown\ndarkorange\nred") into tPropsArray["cBuiltInColors"]

put "don't remove" into tPropsArray["cASKDestroy"]

put "Gray50" into tPropsArray["cSelectionHandle"]

put "128,103" into tPropsArray["cREVMaximizedScriptEditorTopLeft"]

put "true" into tPropsArray["suppressIDE"]

put "Property Inspector" into tPropsArray["cABOptionDoubleClick"]

put "45" into tPropsArray["cREVRotatePrev5"]

put "170,131" into tPropsArray["cPaletteTopLeft"]

put "false" into tPropsArray["cNOPICTWarning"]

put "470,460" into tPropsArray["cREVMsgTopLeft"]

put format("cButtonWidth,100\ncButtonHeight,20\ncTabButtonwidth,250\ncTabButtonHeight,160\ncMenuWidth,130\ncMenuHeight,20\ncFieldWidth,250\ncFieldHeight,160\ncLabelFieldWidth,100\ncLabelFieldHeight,20\ncMacOSScrollbarHeight,16\ncMacOSProgressScrollbarHeight,14\ncScrollbarWidth,200\ncScrollbarHeight,20\ncREVGraphicWidth,120\ncREVGraphicHeight,120\ncREVImageWidth,120\ncREVImageHeight,120\ncREVPlayerWidth,320\ncREVPlayerHeight,256") into tPropsArray["New Field 2"]

put "120" into tPropsArray["cREVGraphicHeight"]

put "Dictionary" into tPropsArray["cRevDocsCurrentCard"]

put "385" into tPropsArray["cREVScriptWidth"]

put "487" into tPropsArray["cREVUnmaximizedScriptWidth"]

put "false" into tPropsArray["cREVDontMaximizeScriptEditor"]

put "true" into tPropsArray["cDontWrap"]

put "false" into tPropsArray["cVariableChecking"]

put "302" into tPropsArray["cAppBrowserWidgetLeft"]

put "true" into tPropsArray["cUngroupWarning"]

put "false" into tPropsArray["resizeable"]

put "false" into tPropsArray["cNavigationArrows"]

put "457,430,853,680" into tPropsArray["cMessageWatcherRect"]

put "287,261" into tPropsArray["cREVMsgTabRectrevbasic"]

put "true" into tPropsArray["cSort"]

put "false" into tPropsArray["cREVMsgAutoRefresh"]

put "true" into tPropsArray["cVariablePreservation"]

put "100" into tPropsArray["cLabelFieldWidth"]

put "false" into tPropsArray["cREVMsgShowUIVariables"]

put "false" into tPropsArray["cHandlerList"]

put "red" into tPropsArray["red"]

put "selectedObject" into tPropsArray["cREVMsgIntelligenceObject"]

put "false" into tPropsArray["cSEHideErrors"]

put "56" into tPropsArray["cFieldHeight"]

put "300" into tPropsArray["cREVUnmaximizedScriptHeight"]

put "13,125" into tPropsArray["cToolsTopLeft"]

put "--" into tPropsArray["cCommentCharacter"]

put "97,92,657,440" into tPropsArray["cScriptEditorRect"]

put "11" into tPropsArray["cREVRotatePrev4"]

put "530,564" into tPropsArray["cREVMsgTabRectrevscript"]

put "146,123,800,408" into tPropsArray["cAppBrowserRect"]

put "true" into tPropsArray["cREVAutoCreateProfilesWarning"]

put "false" into tPropsArray["cREVSaveStacksAfterMoving"]

put "false" into tPropsArray["cREVAutoCreateProfiles"]

put "417,113" into tPropsArray["cREVMsgTabRectGlobal Variables"]

put "118" into tPropsArray["cREVPlayerHeight"]

put "true" into tPropsArray["cShowVideoclips"]

put "false" into tPropsArray["cWholeMatches"]

put "false" into tPropsArray["cVerboseDebug"]

put "417,99" into tPropsArray["cREVMsgTabRectMultipleLines"]

put "true" into tPropsArray["cBreakPoints"]

put "false" into tPropsArray["cREVGeoOpen"]

put "462,120" into tPropsArray["cREVAOTopLeft"]

put "blackgreen" into tPropsArray["cCustomColorsList"]

put "Penguin" into tPropsArray["revHelpUnixReligion"]

put format("cButtonWidth,82\ncButtonHeight,23\ncTabButtonwidth,250\ncTabButtonHeight,160\ncMenuWidth,102\ncMenuHeight,22\ncFieldWidth,250\ncFieldHeight,56\ncLabelFieldWidth,100\ncLabelFieldHeight,21\ncMacOSScrollbarHeight,16\ncMacOSProgressScrollbarHeight,14\ncScrollbarWidth,200\ncScrollbarHeight,16\ncREVGraphicWidth,120\ncREVGraphicHeight,120\ncREVImageWidth,120\ncREVImageHeight,120\ncREVPlayerWidth,155\ncREVPlayerHeight,118") into tPropsArray["cDefaultSizes"]

put "false" into tPropsArray["cSelectGrouped"]

put "false" into tPropsArray["cSEHideMessageBox"]

put "1,2,3,4,5" into tPropsArray["cVideoclipTabs"]

put "true" into tPropsArray["cREVMacOSMenubar"]

put "false" into tPropsArray["cREVProfileReadOnly"]

put "Yellow" into tPropsArray["revHelpHiliteColor"]

put "true" into tPropsArray["cToolbarText"]

put "true" into tPropsArray["cREVScriptDebugMode"]

put "21" into tPropsArray["cLabelFieldHeight"]

put "120" into tPropsArray["cREVGraphicWidth"]

put "417,99" into tPropsArray["cREVMsgTabRectMultiple Lines"]

put "30" into tPropsArray["Num Recent Files"]

put "568,259" into tPropsArray["cREVProfileEditorTopLeft"]

put "417,113" into tPropsArray["cREVMsgTabRectfrontScripts"]

put "11" into tPropsArray["cREVRotatePrev3"]

put "338" into tPropsArray["cREVButtonSecondTabHeight"]

put "true" into tPropsArray["cREVHelpText"]

put "160" into tPropsArray["cTabButtonHeight"]

put "287,261" into tPropsArray["cREVMsgTabRectrevstack"]

put "417,113" into tPropsArray["cREVMsgTabRectGlobal Properties"]

put "true" into tPropsArray["cShowAudioclipclips"]

put "revolutionli" into tPropsArray["cREVDBName"]

put "true" into tPropsArray["cDocsQuickLinksVisible"]

put "true" into tPropsArray["cStartPageShow"]

put "278" into tPropsArray["cREVErrorsPaletteExpandedHeight"]

put "true" into tPropsArray["cShowAudioclips"]

put "filtering" into tPropsArray["revHelpListMethod"]

set the customProperties[""] of stack "revPreferences" to tPropsArray

delete variable tPropsArray

-- cABDoubleClick

put "Play" into tPropsArray["videoclips"]

put "Toplevel" into tPropsArray["stacks"]

put "Property Inspector" into tPropsArray["controls"]

put "Play" into tPropsArray["audioclips"]

put "Go" into tPropsArray["cards"]

set the customProperties["cABDoubleClick"] of stack "revPreferences" to tPropsArray

delete variable tPropsArray

-- cABCommandDoubleClick

put "Edit Script" into tPropsArray["videoclips"]

put "Edit Script" into tPropsArray["stacks"]

put "Edit Script" into tPropsArray["controls"]

put "Edit Script" into tPropsArray["audioclips"]

put "Edit Script" into tPropsArray["cards"]

set the customProperties["cABCommandDoubleClick"] of stack "revPreferences" to tPropsArray

delete variable tPropsArray

-- cABOptionDoubleClick

put "Property Inspector" into tPropsArray["videoclips"]

put "Property Inspector" into tPropsArray["stacks"]

put "Property Inspector" into tPropsArray["controls"]

put "Property Inspector" into tPropsArray["audioclips"]

put "Property Inspector" into tPropsArray["cards"]

set the customProperties["cABOptionDoubleClick"] of stack "revPreferences" to tPropsArray

delete variable tPropsArray

revInternal__SavePreferences

end revInternal__ResetPreferences

--------------------------------------------------------------------------------

-- Internal Utility Functions

--

--

local sSavePreferencesMessage

command revInternal__SavePreferences

cancel sSavePreferencesMessage

send "__revInternal_SavePreferences" to me in 500 milliseconds

put the result into sSavePreferencesMessage

end revInternal__SavePreferences

command __revInternal_SavePreferences

lock messages

-- MM-2014-02-22: [[ Bug 11442 ]] Saving the prefs stack when security permissions is true is not possible.

try

save stack "revPreferences" with format "7.0"

catch tError

end try

unlock messages

end __revInternal_SavePreferences

private command revInternal__EnsureFolder pFolder

revInternal__Log "Enter", "Ensuring Folder '" & pFolder & "'"

local tPath

local tComponent

set the itemDelimiter to "/"

put item 1 of pFolder & "/" into tPath

repeat for each item tComponent in item 2 to -1 of pFolder

put tComponent & "/" after tPath

if there is no folder (char 1 to -2 of tPath) then

create folder char 1 to -2 of tPath

if the result is empty then

revInternal__Log "Message", "Creation of folder '" & char 1 to -2 of tPath & "' succeeded"

else

revInternal__Log "Message", "Creation of folder '" & char 1 to -2 of tPath & "' failed"

end if

end if

end repeat

revInternal__Log "Leave", "Ensuring Folder '" & pFolder & "'"

end revInternal__EnsureFolder

function revInternal__CheckFileAssociations

local tEnginePath

set the itemDelimiter to ":"

put item 2 to -1 of the address into tEnginePath

if the platform is "win32" then

-- If .rev, .livecode or .livecodescript classes are not present, then we need new assocs

# AL-2015-03-13: [[ Bug 14910 ]] Add .livecodescript to valid stack file extensions on windows

if queryRegistry("HKEY_CURRENT_USER\Software\Classes\.rev\") is not "RevolutionStack" or \

queryRegistry("HKEY_CURRENT_USER\Software\Classes\.livecode\") is not "LiveCodeStack" or \

queryRegistry("HKEY_CURRENT_USER\Software\Classes\.livecodescript\") is not "LiveCodeScriptOnlyStack"

then

return true

end if

-- If .rev, .livecode or .livecodescript classes are not present, then we need new assocs

# AL-2015-03-13: [[ Bug 14910 ]] Add .livecodescript to valid stack file extensions on windows

replace slash with backslash in tEnginePath

get queryRegistry("HKEY_CURRENT_USER\Software\Classes\RevolutionStack\Shell\Open\Command\")

if word 1 of it is not quote & tEnginePath & quote then

return true

end if

get queryRegistry("HKEY_CURRENT_USER\Software\Classes\LiveCodeStack\Shell\Open\Command\")

if word 1 of it is not quote & tEnginePath & quote then

return true

end if

get queryRegistry("HKEY_CURRENT_USER\Software\Classes\LiveCodeScriptOnlyStack\Shell\Open\Command\")

if word 1 of it is not quote & tEnginePath & quote then

return true

end if

else

-- Do Linux at some point!

end if

return false

end revInternal__CheckFileAssociations

command revInternal__InstallFileAssociations

local tEnginePath

set the itemDelimiter to ":"

put item 2 to -1 of the address into tEnginePath

if the platform is "win32" then

replace slash with backslash in tEnginePath

# AL-2015-03-13: [[ Bug 14910 ]] Add .livecodescript to valid stack file extensions on windows

get setRegistry("HKEY_CURRENT_USER\Software\Classes\.rev\", "RevolutionStack") and \

setRegistry("HKEY_CURRENT_USER\Software\Classes\RevolutionStack\Shell\Open\Command\", quote & tEnginePath & quote && quote & "%1" & quote) and \

setRegistry("HKEY_CURRENT_USER\Software\Classes\RevolutionStack\DefaultIcon\", tEnginePath & comma & "1") and \

setRegistry("HKEY_CURRENT_USER\Software\Classes\.livecode\", "LiveCodeStack") and \

setRegistry("HKEY_CURRENT_USER\Software\Classes\LiveCodeStack\Shell\Open\Command\", quote & tEnginePath & quote && quote & "%1" & quote) and \

setRegistry("HKEY_CURRENT_USER\Software\Classes\LiveCodeStack\DefaultIcon\", tEnginePath & comma & "1") and \

setRegistry("HKEY_CURRENT_USER\Software\Classes\.livecodescript\", "LiveCodeScriptOnlyStack") and \

setRegistry("HKEY_CURRENT_USER\Software\Classes\LiveCodeScriptOnlyStack\Shell\Open\Command\", quote & tEnginePath & quote && quote & "%1" & quote) and \

setRegistry("HKEY_CURRENT_USER\Software\Classes\LiveCodeScriptOnlyStack\DefaultIcon\", tEnginePath & comma & "1")